VBA Excel. Рабочая книга (открыть, создать новую, закрыть)

Открытие книги Excel из кода VBA. Проверка существования книги. Создание новой книги, обращение к открытой книге и ее закрытие. Методы Open, Add и Close.

Содержание

1. Открытие существующей книги

2. Проверка существования файла

3. Создание новой книги

4. Обращение к открытой книге

5. Как закрыть книгу Excel из кода VBA

Открытие существующей книги

Существующая книга открывается из кода VBA Excel с помощью метода Open:

1	Workbooks.Open Filename:="D:\test1.xls"

или

1	Workbooks.Open ("D:\test1.xls")

В кавычках указывается полный путь к открываемому файлу Excel. Если такой файл не существует, произойдет ошибка.

Проверка существования файла

Проверить существование файла можно с помощью функции Dir. Проверка существования книги Excel:

If Dir("D:\test1.xls") = "" Then

MsgBox "Файл не существует"

Else

MsgBox "Файл существует"

End If

Или, если файл (книга Excel) существует, можно сразу его открыть:

If Dir("D:\test1.xls") = "" Then

MsgBox "Файл не существует"

Else

Workbooks.Open Filename:="D:\test1.xls"

End If

Создание новой книги

Новая рабочая книга Excel создается в VBA с помощью метода Add:

1	Workbooks.Add

Созданную книгу, если она не будет использоваться как временная, лучше сразу сохранить:

1 2	Workbooks.Add ActiveWorkbook.SaveAs Filename:="D:\test2.xls"

В кавычках указывается полный путь сохраняемого файла Excel, включая присваиваемое имя, в примере — это «test2.xls».

Обращение к открытой книге

Обращение к активной книге:

1	ActiveWorkbook

Обращение к книге с выполняемым кодом:

1	ThisWorkbook

Обращение к книге по имени:

1 2	Workbooks("test1.xls") Workbooks("test2.xls")

Обратиться по имени можно только к уже открытой книге, а чтобы из кода VBA Excel книгу открыть, необходимо указать полный путь к файлу.

Как закрыть книгу Excel из кода VBA

Открытая рабочая книга закрывается из кода VBA Excel с помощью метода Close:

1	Workbooks("test1.xlsx").Close

Если закрываемая книга редактировалась, а внесенные изменения не были сохранены, тогда при ее закрытии Excel отобразит диалоговое окно с вопросом: Вы хотите сохранить изменения в файле test1.xlsx? Чтобы файл был закрыт без сохранения изменений и вывода диалогового окна, можно воспользоваться параметром метода Close — SaveChanges:

1	Workbooks("test1.xlsx").Close SaveChanges:=False

или

1	Workbooks("test1.xlsx").Close (False)

Закрыть книгу Excel из кода VBA с сохранением внесенных изменений можно также с помощью параметра SaveChanges:

1	Workbooks("test1.xlsx").Close SaveChanges:=True

или

1	Workbooks("test1.xlsx").Close (True)

Фразы для контекстного поиска: открыть книгу, открытие книги, создать книгу, создание книги, закрыть книгу, закрытие книги, открыть файл Excel, открытие файла Excel, существование книги, обратиться к открытой книге.

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

40 комментариев для “VBA Excel. Рабочая книга (открыть, создать новую, закрыть)”

1 05.02.2020 в 13:04

А что делать если открываемая книга спрашивает, стоит ли ей обновляться и выполнение кода приостанавливается, пока пользователь не нажмёт кнопку? Как скрывать это сообщение? Пытался писать

1

Application.DisplayAlerts = 0

или

1

Application.DisplayAlerts = False

— не помогает
1. Евгений 05.02.2020 в 15:12
  
  Если речь идет об обновлении связей между книгами, то попробуйте так:
  
  1
  
  Application.AskToUpdateLinks = False
2. 1. Сбитый Лётчик Небосводов 13.02.2022 в 23:26
    
    Лучше
    
    1
    
    Workbooks.Open ("D:\test1.xls", 0)
    
    т.к. в других местах обновление, возможно, нужно.
  2. 1. Мария 28.04.2022 в 04:53
      
      Жаль, спасибо.
      Кстати, если вдруг кому-то нужно, изменить название excel в шапке документа (но при сохранении всё равно будет предлагаться «Книга n»), то можно сделать так:
      
      1
      
      Application.ActiveWindow.Caption = "моё название"
Вячеслав 25.08.2020 в 22:45

Здравствуйте.
А как поступить, если имя книги заранее неизвестно. Есть-ли в VBA что-нибудь вроде диалогового окна «Открыть книгу».
Или, допустим, поиск всех книг в определённой папке.
1. Евгений 25.08.2020 в 22:58
  
  Здравствуйте, Вячеслав!
  Для выбора книги в определённой папке используйте Стандартный диалог выбора файлов Application.GetOpenFilename.
Сергей 10.03.2021 в 17:50

Добрый!
Из Аутлука открываю эксель файл. Имя его каждый раз — разное. Как закрыть его так, чтобы при этом закрывалось само приложение Эксель? Сохранять изменения не нужно.
Код:

1

ActiveWorkbook.Close SaveChanges:=False

закрывает саму книгу, но при этом сама прога остаётся висеть со своим интерфейсом. Можно нажать Ctlr+O и открыть какой-нибудь xls-файл.
При этом на компе могут быть открыты другие файлы, поэтому команда

1

Application.Quit

не допустима.
Что делать?

Евгений 10.03.2021 в 19:28

Сергей, используйте глобальные переменные, если файл Excel открывается и закрывается разными процедурами (переменные позволят закрыть тот самый файл и тот самый экземпляр приложения, в котором открыт файл):

Option Explicit

Public myExcel As Object, myWorkbook As Object

Sub OpenExcelWorkbook()

Set myExcel = CreateObject("Excel.Application")

Set myWorkbook = myExcel.Workbooks.Open("C:\Users\...xlsx")

myExcel.Visible = True

End Sub

Sub CloseExcelWorkbook()

myWorkbook.Close SaveChanges:=False

myExcel.Quit

Set myWorkbook = Nothing

Set myExcel = Nothing

End Sub

YAN 16.04.2021 в 14:00

А как открывать книгу, если имя файла совпадает с названием из массива.
То есть есть массив переменных которые записаны в столбец начиная с столбца А строки 2. Названия всегда разные.но совпадают с названием файла. Можно ли поочередно открыть их для редактирования через VBA

Евгений 16.04.2021 в 18:03

Привет, YAN!
Используйте следующий код для открытия по очереди файлов Excel, имена которых записаны в первый столбец со второй ячейки:

Dim n As Long

Private Sub CommandButton1_Click()

Workbooks.Open ("C:\Users\Public\" & Cells(n + 2, 1))

n = n + 1

If n + 2 > 15 Then n = 0

End Sub

Объявление глобальной переменной n размещено в разделе Declarations программного модуля. Число 15 соответствует номеру строки последней ячейки диапазона с именами рабочих книг.

0mega 29.04.2021 в 05:42

имеется 2 книги (обе открытые)

Книга 1 Лист1 ячейка D4 формула ссылается на вторую книгу
='[Книга 2.xls]Лист1′!$F$5

Используя ссылку (без ручного ввода) надо обратиться Книга 2, скопировать 5 строк ниже ссылки (строка6:строка10) и вставить в рабочую книгу(Книга 1)

Евгений 29.04.2021 в 11:32

0mega, а '[Книга 2.xls]Лист1'!$F$5 — это постоянное значение? И в какое место какого листа Книги 1 строки должны быть вставлены?

0mega 29.04.2021 в 14:35

«… а '[Книга 2.xls]Лист1'!$F$5 – это постоянное значение? …»
Нет !
Сценарий такой.
В бухгалтерии есть такой термин «Инвентаризация»
В связи с пандемией — движение по складу было минимальное. Большинство позиций остались нетронутыми.
Значит нет необходимости «набивать мозоли» на повторном вводе.
Я вижу такое решение
Есть Книга1.
Юзер открывает прошлогодний файл и (напр. в ячейке F5) визуально сравнивает итоговые значения с настоящими.
если показания совпадают — тогда проверяется Лист2, Лист3…потом будет другая книга
Если значение F5 (это тоже не постоянный адрес ) не совпадает с реальным, тогда в Книга1 юзер ставит «=» и кликает на F5 другой книги
В Книге1 автоматически формируется адрес неправильного значения.
Теперь топчем кнопочку макроса.
макрос берет адрес из ссылки и обращается ко второй Книге, копирует нужный мне массив и загружает в Первую книгу.
Юзер лечит (меняет, добавляет, редактирует ) больной массив и отправляет обратно.
Возможно есть какой-то более простой способ, но «самая короткая дорога — это та которую ты знаешь»

Евгений 29.04.2021 в 19:45

Этот код VBA копирует пять строк под указанной ячейкой из открытой книги Excel по адресу из ячейки D4 Листа1 текущей книги и вставляет их в текущую книгу в пять строк под ячейкой D4 Листа1:

Sub Primer()

Dim s As String, n1 As Long, n2 As Long

s = ThisWorkbook.Sheets("Лист1").Range("D4").Formula

n1 = Range(s).Row

n2 = InStr(s, "!")

s = Left(s, n2) & n1 + 1 & ":" & n1 + 6

Range(s).Copy ThisWorkbook.Sheets("Лист1").Rows("5:9")

End Sub

Предыдущие варианты кода я удалил, так как этот — самый простой и надежный.

1. 0mega 30.04.2021 в 23:04
  
  Евгений, спасибо за уделенное время.
  Все работает как я заказывал.
  Есть маленькая просьба.
  Стартовый вопрос имел «упрощенный вид». И чтобы вас не нагружать, я предполагал что смогу самостоятельно «запилить» под себя
  Ошибся!
  Что надо изменить чтобы макрос копировал не 5 строк, а 3 000 (с 1-ой по 3000-ую) ?
  
  и еще 1 вопрос:
  После редактирования надо Range(«A1:AZ3000») из рабочей книги (Книга1) отправить обратно (Книга2 на лист, который был указан в ссылке) ?

Евгений 01.05.2021 в 07:25

Option Explicit

Dim s As String

Sub Книга2Книга1()

Dim n As Long

s = ThisWorkbook.Sheets("Лист1").Range("D4").Formula

n = InStr(s, "!")

s = Left(s, n) & "A1:AZ3000"

Range(s).Copy ThisWorkbook.Sheets("Лист1").Range("A1:AZ3000")

End Sub

Sub Книга1Книга2()

ThisWorkbook.Sheets("Лист1").Range("A1:AZ3000").Copy Range(s)

End Sub

1. 0mega 01.05.2021 в 20:18
  
  Спасибо. Все работает
  то что врач прописал

0mega 22.05.2021 в 08:14

Евгений, что и как надо изменить чтобы учитывалась высота строк и ширина столбцов ?

Евгений 22.05.2021 в 10:24

Копировать высоту строк и ширину столбцов из Книги2 в Книгу1 или наоборот?

0mega 22.05.2021 в 11:53

Есть книга 2 (донор, образец)
Есть книга 1 (Workbook)

Машина копирует файл у «донора» (вторая) книги и помещает в первую (активную, рабочую) книгу
Надо чтобы в первой книге была точная копия как в доноре

Евгений 22.05.2021 в 14:03

Если все-таки не файл, а диапазон, тогда так:

Dim i As Long

With ThisWorkbook.Sheets("Лист1").Range("A1:AZ3000")

For i = 1 To .Rows.Count

.Rows(i).RowHeight = Range(s).Rows(i).RowHeight

For i = 1 To .Columns.Count

.Rows(i).RowHeight = Range(s).Rows(i).RowHeight

.Columns(i).ColumnWidth = Range(s).Columns(i).ColumnWidth

End With

Роман 05.06.2021 в 22:58

Здравствуйте!
Подскажите, Запускаю макрос и при сохранении книги появляется диалоговое окно о Замене, Как можно сохранить книгу без вопроса замены с помощью макроса. Чтобы замена происходила, но диалоговое окно не появлялось?
Спасибо Вашему сайту!

Евгений 06.06.2021 в 00:19

Здравствуйте, Роман!
Отключите оповещения перед строками кода, при выполнении которых не должны выводиться диалоговые окна, и не забудьте включить показ сообщений после тех строк:

Application.DisplayAlerts = False 'Отключение вывода сообщений

'строки кода, при выполнении которых оповещения должны быть отключены

Application.DisplayAlerts = True 'Включение вывода сообщений

1. Роман 06.06.2021 в 19:00
  
  Все работает, от души Спасибо!

0mega 25.07.2021 в 22:27

есть 2 книги
Book 1
Sheet1
Cells (n, «D») = 25.07. 21 (дата 25 июля 2021 г)
Надо в Book2 на Sheet1 в столбце «F» найти такую же дату,
— скопировать столбцы «J»; «L» и «N» от даты и до конца таблицы
— вставить в Book1 Sheet1 Range(Cells(n,»F»),Cells(9999,»H»))
1. Евгений 26.07.2021 в 11:12
  
  На каком этапе возникло затруднение?
0mega 26.07.2021 в 11:31

сложности в том чтобы в другой книге найти информацию, которая (задается/определяется)в рабочей книге.
Без проблем напишу нужный мне код если это все будет в одной книге.
В качестве плана «Б» предполагается скопировать лист из другой книг и вставить в WorkBook.
потом сделать все что надо и удалить лист-донор.
Но при таком подходе больше половины — это лишняя работа

Евгений 26.07.2021 в 13:39

Sub Primer()

Dim myBook As Workbook, myRange As Range, myCell As Range, n As Long

'Открываем вторую книгу, которая, возможно, должна быть закрыта

'(у меня код работает без ошибок и с открытой второй книгой)

Set myBook = Workbooks.Open("C:\Users\0mega\Downloads\Book2.xlsx", ReadOnly:=True)

'Присваиваем переменной myRange заполненный диапазон столбца "F"

With myBook.Worksheets("Sheet1")

Set myRange = .Range(.Range("F1"), .Range("F1").End(xlDown))

End With

'Ищем в столбце "F" ячейку с нужной датой и присваиваем переменной n номер ее строки

For Each myCell In myRange

If myCell = "25.07. 21" Then

n = myCell.Row

Exit For

End If

'Здесь копируете столбцы, которые можно поочередно

'присваивать переменной myRange и вставлять в первую книгу

'Закрываем файл Book2.xlsx

myBook.Close SaveChanges:=False

End Sub

0mega 26.07.2021 в 15:16

Евгений, похоже я объяснил недостаточно грамотно …
If myCell = "25.07. 21" Then
Это как раз и есть тот самый камень преткновения .
"25.07. 21" — это ПЕРЕМЕННОЕ значение , которое каждый раз меняется
Во второй книге машина должна найти такое же значение как в первой книге, в ячейке (n,»D»)
в формульном исполнении это будет так:
=ПОИСКПОЗ(D14;[Book2.xlsx]Sheet1!$F:$F;0)
во второй книге на первом Листе в столбце «F» ищем значение такое же как в первой книге в ячейке D14

Евгений 26.07.2021 в 15:43

Имя переменной я изменил, так как n в моем примере уже используется.

For Each myCell In myRange

If myCell = ThisWorkbook.Worksheets("Sheet1").Cells(n1, "D") Then

n = myCell.Row

Exit For

End If

0mega 26.07.2021 в 15:54

Сейчас нет возможности проверить.
Отпишусь позже
0mega 28.07.2021 в 13:51

именно так я и хотел
спасибо
Мария 27.04.2022 в 12:39

Добрый день! Excel создали, ещё не сохраняли (сохранять будет сам пользователь). Можно изменить название «Книга 1» на своё без сохранения? Это чтобы пользователю не приходилось при сохранении менять имя exel «Книга 1»
1. Евгений 27.04.2022 в 23:12
  
  Здравствуйте, Мария!
  По моему, это невозможно.
Андрей 18.11.2022 в 14:30

Добрый день.
Открываю книгу методом Workbooks.Open Filename:="D:\test1.xls"
В самой книге несколько листов, макросы и кнопки.
При открытии книга активирует режим конструктора. Не пониманию почему это происходит и как этого избежать?
Из-за этого режима дальше не работает код.
1. Евгений 18.11.2022 в 15:23
  
  Добрый день, Андрей!
  Найдите в модуле книги, которая открывается в режиме конструктора, строку с методом .ToggleFormsDesign и закомментируйте ее.
  
  Если такой строки нет, попробуйте следующий вариант:
  
  1
  2
  
  Workbooks.Open Filename:="D:\test1.xls"
  Application.CommandBars.FindControl(ID:=1605).Reset
Андрей 21.11.2022 в 11:01

Спасибо за оперативный ответ.
1. Я пробовал этот вариант и другие из этой серии, ничего не помогало.
2. Проверил, что макрос работает и при режиме конструктора, то есть дело не в этом.
2. Разобрался, что если запускать макрос через кнопку, то все работает, а если через горячие клавиши, то макрос только открывает файл и дальше не выполняется. Буду разбираться в этом направлении.
Akmal 15.05.2023 в 07:14

Здравствуйте. как можно открыть файлы на отдельном экземпляре?

Евгений 15.05.2023 в 21:03

Здравствуйте, Akmal!
Сначала надо создать новый экземпляр приложения Excel (в примере он создается сразу при объявлении переменной), открыть книгу и сделать новый экземпляр Excel видимым, так как изначально он будет открыт в фоновом режиме:

Sub Primer()

Dim myExcel As New Excel.Application

With myExcel

.Workbooks.Open "C:\Тестовая\НоваяКнига.xlsx"

.Visible = True

End With

End Sub

1. Akmal 16.05.2023 в 06:11
  
  спс за ответ Женя.
  попробуем вдруг получится.

Обсуждение закрыто.