VBA Excel. Рабочий лист (создание, копирование, удаление)

Создание, копирование, перемещение и удаление рабочих листов Excel с помощью кода VBA. Методы Sheets.Add, Worksheet.Copy, Worksheet.Move и Worksheet.Delete.

Содержание

1. Создание новых листов

1.1. Синтаксис метода Sheets.Add

1.2. Компоненты метода Sheets.Add

1.3. Примеры создания листов

2. Копирование листов

2.1. Синтаксис метода Worksheet.Copy

2.2. Компоненты метода Worksheet.Copy

2.3. Примеры копирования листов

3. Перемещение листов

3.1. Синтаксис метода Worksheet.Move

3.2. Компоненты метода Worksheet.Move

3.3. Примеры перемещения листов

4. Удаление листов

4.1. Синтаксис метода Worksheet.Delete

4.2. Примеры удаления листов

Создание новых листов

Создание новых рабочих листов осуществляется с помощью метода Sheets.Add.

Синтаксис метода Sheets.Add

expression.Add [Before, After, Count, Type]

где expression — переменная, представляющая собой объект Sheet.

Компоненты метода Sheets.Add

Before* — необязательный параметр типа данных Variant, указывающий на лист, перед которым будет добавлен новый.
After* — необязательный параметр типа данных Variant, указывающий на лист, после которого будет добавлен новый.
Count — необязательный параметр типа данных Variant, указывающий, сколько листов будет добавлено (по умолчанию — 1).
Type — необязательный параметр типа данных Variant, указывающий тип листа: xlWorksheet** (рабочий лист) или xlChart (диаграмма), по умолчанию — xlWorksheet.

*Если Before и After не указаны, новый лист, по умолчанию, будет добавлен перед активным листом.

**Для создания рабочего листа (xlWorksheet) можно использовать метод Worksheets.Add, который для создания диаграмм уже не подойдет.

Примеры создания листов

'Создание рабочего листа:

Sheets.Add

Worksheets.Add

ThisWorkbook.Sheets.Add After:=ActiveSheet, Count:=2

Workbooks("Книга1.xlsm").Sheets.Add After:=Лист1

Workbooks("Книга1.xlsm").Sheets.Add After:=Worksheets(1)

Workbooks("Книга1.xlsm").Sheets.Add After:=Worksheets("Лист1")

'Создание нового листа с заданным именем:

Workbooks("Книга1.xlsm").Sheets.Add.Name = "Мой новый лист"

'Создание диаграммы:

Sheets.Add Type:=xlChart

'Добавление нового листа перед

'последним листом рабочей книги

Sheets.Add Before:=Sheets(Sheets.Count)

'Добавление нового листа в конец

Sheets.Add After:=Sheets(Sheets.Count)

Лист1 в After:=Лист1 — это уникальное имя листа, указанное в проводнике редактора VBA без скобок.
Лист1 в After:=Worksheets(«Лист1») — это имя на ярлыке листа, указанное в проводнике редактора VBA в скобках.

Создаваемый лист можно присвоить объектной переменной:

Dim myList As Object

'В активной книге

Set myList = Worksheets.Add

'В книге «Книга1.xlsm»

Set myList = Workbooks("Книга1.xlsm").Worksheets.Add

'Работаем с переменной

myList.Name = "Listok1"

myList.Cells(1, 1) = myList.Name

'Очищаем переменную

Set myList = Nothing

Если создаваемый лист присваивается объектной переменной, он будет помещен перед активным листом. Указать дополнительные параметры невозможно.

Копирование листов

Копирование рабочих листов осуществляется с помощью метода Worksheet.Copy.

Синтаксис метода Worksheet.Copy

expression.Copy [Before, After]

где expression — переменная, представляющая собой объект Worksheet.

Компоненты метода Worksheet.Copy

Before* — необязательный параметр типа данных Variant, указывающий на лист, перед которым будет добавлена копия.
After* — необязательный параметр типа данных Variant, указывающий на лист, после которого будет добавлена копия.

*Если Before и After не указаны, Excel создаст новую книгу и поместит копию листа в нее. Если скопированный лист содержит код в проекте VBA (в модуле листа), он тоже будет перенесен в новую книгу.

Примеры копирования листов

'В пределах активной книги

'(уникальные имена листов)

Лист1.Copy After:=Лист2

'В пределах активной книги

'(имена листов на ярлычках)

Worksheets("Лист1").Copy Before:=Worksheets("Лист2")

'Вставить копию в конец

Лист1.Copy After:=Sheets(Sheets.Count)

'Из одной книги в другую

Workbooks("Книга1.xlsm").Worksheets("Лист1").Copy _

After:=Workbooks("Книга2.xlsm").Worksheets("Лист1")

'Один лист активной книги в новую книгу

Лист1.Copy

'Несколько листов активной книги в новую книгу*

Sheets(Array("Лист1", "Лист2", "Лист3")).Copy

'Все листы книги с кодом в новую книгу

ThisWorkbook.Worksheets.Copy

* Если при копировании в новую книгу нескольких листов хотя бы один лист содержит умную таблицу — копирование невозможно. Один лист, содержащий умную таблицу, копируется в новую книгу без проблем.

Если рабочие книги указаны как элементы коллекции Workbooks, в том числе ActiveWorkbook и ThisWorkbook, листы нужно указывать как элементы коллекции Worksheets, использование уникальных имен вызовет ошибку.

Перемещение листов

Перемещение рабочих листов осуществляется с помощью метода Worksheet.Move.

Синтаксис метода Worksheet.Move

expression.Move [Before, After]

где expression — переменная, представляющая собой объект Worksheet.

Компоненты метода Worksheet.Move

Before* — необязательный параметр типа данных Variant, указывающий на лист, перед которым будет размещен перемещаемый лист.
After* — необязательный параметр типа данных Variant, указывающий на лист, после которого будет размещен перемещаемый лист.

*Если Before и After не указаны, Excel создаст новую книгу и переместит лист в нее.

Примеры перемещения листов

Простые примеры перемещения листов:

'В пределах активной книги

'(уникальные имена листов)

Лист1.Move After:=Лист2

'В пределах активной книги

'(имена листов на ярлычках)

Worksheets("Лист1").Move Before:=Worksheets("Лист2")

'Размещение после последнего листа:

Лист1.Move After:=Sheets(Sheets.Count)

'Из одной книги в другую

Workbooks("Книга1.xlsm").Worksheets("Лист1").Move _

After:=Workbooks("Книга2.xlsm").Worksheets("Лист1")

'В новую книгу

Лист1.Move

Перемещение листа «Лист4» в позицию перед листом, указанным как по порядковому номеру, так и по имени ярлыка:

Sub Peremeshcheniye()

Dim x

x = InputBox("Введите имя или номер листа", "Перемещение листа «Лист4»")

If IsNumeric(x) Then x = CLng(x)

Sheets("Лист4").Move Before:=Sheets(x)

End Sub

Удаление листов

Удаление рабочих листов осуществляется с помощью метода Worksheet.Delete

Синтаксис метода Worksheet.Delete

expression.Delete

где expression — переменная, представляющая собой объект Worksheet.

Примеры удаления листов

'По уникальному имени

Лист1.Delete

'По имени на ярлычке

Worksheets("Лист1").Delete

'По индексу листа

Worksheets(1).Delete

'В другой книге

Workbooks("Книга1.xlsm").Worksheets("Лист1").Delete

Как обратиться к рабочему листу, переименовать, скрыть или отобразить его с помощью кода VBA Excel, смотрите в этой статье.

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

69 комментариев для “VBA Excel. Рабочий лист (создание, копирование, удаление)”

Мон 24.02.2020 в 07:06

А как удалить листы не указывая постоянно их название?:

Евгений 24.02.2020 в 15:04

Привет, Мон!
Можно удалить все листы, кроме указанных в условии, с помощью цикла For Each … Next:

Sub Primer()

Dim mySheet As Worksheet

For Each mySheet In ThisWorkbook.Sheets

If mySheet.Name <> "Лист1" Then

mySheet.Delete

End If

End Sub

Сергей 24.07.2020 в 21:13

Если по крупному
нет Проверки наличия Листа в книге
нет Переименования Листа
1. Евгений 24.07.2020 в 21:26
  
  Привет, Сергей!
  Переименование листов есть в статье VBA Excel. Рабочий лист (обращение, переименование, скрытие).
2. Евгений 25.07.2020 в 14:10
  
  Добавил статью VBA Excel. Проверка существования листа.
Эдуард 04.08.2020 в 14:26

Добрый день! не могу сделать в макросе — чтобы сделанному скопированному листу присваивалось свое имя, которое при новом запуске макроса новому листу будет присваивать новое имя из этой книги (переменное)
1. Евгений 04.08.2020 в 15:35
  
  Добрый день, Эдуард!
  Я правильно понял вопрос: нужно, чтобы макрос при каждом запуске создавал копию листа и присваивал ему новое имя, отличное от имени по умолчанию? Если так, то по каким правилам должно создаваться новое имя?
Вадим 30.11.2020 в 22:41

Здравствуйте. Не могу найти макрос может кто поможет.
Задача состоит в том что бы макрос читал все листы книги после чего делал копию этих листов и вставлял в эти же листы данные как значения. Т.е. фактически разрывал связи методом копи паст но на всех листах книги (колличество листов в книге может быть каждый раз разное.

Артур 05.05.2021 в 20:17

Добрый день!
У меня вопрос.
Как перемещать лист перед другим листом, номер или название которого будет вводить пользователь?

Евгений 05.05.2021 в 23:14

Привет, Артур!
Перемещение листа «Лист2» на позицию перед листом, имя ярлыка которого вводится в текстовое поле информационного окна InputBox:

Sub Peremeshcheniye()

Dim x As String

x = InputBox("Введите имя листа", "Перемещение листа «Лист2»")

Worksheets("Лист2").Move Before:=Worksheets(x)

End Sub

Артур 06.05.2021 в 06:40

Спасибо!
У меня ещё вопрос. А если указывать номер листа, перед которым будет другой лист, какое изменение будет в коде?

Евгений 06.05.2021 в 09:57

1	Dim x As Long

А так можно вводить и номер, и имя:

Sub Peremeshcheniye()

Dim x

x = InputBox("Введите имя или номер листа", "Перемещение листа «Лист2»")

If IsNumeric(x) Then x = CLng(x)

Worksheets("Лист2").Move Before:=Worksheets(x)

End Sub

Артур 06.05.2021 в 12:24

Бладораю.
У меня последний вопрос.
Нужно, чтобы при отмене операции по перемещению не было ошибок. Я пробовал с If… Then GoTo, но не выходит.

Евгений 06.05.2021 в 20:33

Option Explicit

Dim n1 As Long, n2 As Long

Sub Peremeshcheniye()

Dim x

x = InputBox("Введите имя или номер листа", "Перемещение листа «Лист2»")

If IsNumeric(x) Then x = CLng(x)

With Sheets("Лист2")

n1 = .Index

.Move Before:=Sheets(x)

n2 = .Index

End With

End Sub

Sub Otmena()

If n1 > n2 Then

Sheets("Лист2").Move After:=Sheets(n1)

Else

Sheets("Лист2").Move Before:=Sheets(n1)

End If

End Sub

Эдуард 17.01.2021 в 13:52

Добрый день! Возможно ли полное копирование листа на нужный мне лист? В январе заполняются данные каждый день и надо чтобы за каждый день создавалась копия на заранее созданные 31 лист по дням?

Sub Wsh_PasteSpecial()

Dim WshSrc As Worksheet

Dim WshTrg As Worksheet

Rem Set working worksheets

Set WshSrc = ThisWorkbook.Worksheets("Січень")

Set WshTrg = ThisWorkbook.Worksheets("14")

Sheets("14").Activate

WshSrc.Cells.Copy

With WshTrg.Cells

.PasteSpecial Paste:=xlPasteColumnWidths

.PasteSpecial Paste:=xlPasteFormats

.PasteSpecial Paste:=xlPasteFormulasAndNumberFormats

Application.CutCopyMode = False

End With

End Sub

Евгений 17.01.2021 в 14:52

Добрый день, Эдуард!
Это можно сделать двумя строками, но перед копированием следует проверить, не был ли исходный лист сегодня уже сохранен под новым именем:

Sub Wsh_PasteSpecial()

Dim d As String, WshSrc As Worksheet

d = CStr(Day(Date))

'проверяем, что лист сегодня еще не был сохранен

For Each WshSrc In ThisWorkbook.Worksheets

If WshSrc.Name = d Then

MsgBox "Лист за " & FormatDateTime(Date, vbShortDate) & " уже сохранен!"

Exit Sub

End If

'копируем лист в конец книги

Worksheets("Січень").Copy After:=Worksheets(Worksheets.Count)

'присваиваем листу в качестве имени число текущей даты

ActiveSheet.Name = d

End Sub

Эдуард 17.01.2021 в 15:15

Спасибо за помощь! Нашел другое решение более мне подходящее но не знаю как сделать чтобы созданые листы вставлялись по порядку нумерации 1,2,3 и т.д. после активного листа? Не поможете вот код

Sub NewSheet()

Dim origSht As Worksheet

Dim destSht As Worksheet

On Error GoTo eHandle

Set origSht = ActiveSheet

Sheets.Add.Name = InputBox("Введите дату")

Set destSht = ActiveSheet

origSht.Cells.Copy Destination:=destSht.Cells

Exit Sub

eHandle:

MsgBox "Такая дата существует - введите другую"

Set origSht = Nothing

Set destSht = Nothing

End Sub

1. Евгений 17.01.2021 в 15:27
  
  1
  2
  
  Set destSht = ActiveSheet
  destSht.Move After:=Worksheets(Worksheets.Count)
2. 1. Эдуард 17.01.2021 в 15:36
    
    Спасибо все работает!

Эдуард 17.01.2021 в 18:06

Еще вопрос, можно ли скопировать лист не в конец книги а между листами, есть 12 месяцев в книге ексель чтобы копировалось после января, февраля?
Эдуард 17.01.2021 в 18:17

И может еще чтобы кнопка с макросом не копировалась а создавалась гипперссылка обратно на лист?

Эдуард 17.01.2021 в 18:18

Sub NewSheet()

Dim origSht As Worksheet

Dim destSht As Worksheet

On Error GoTo eHandle

Set origSht = ActiveSheet

Sheets.Add.Name = InputBox("Ввести дату - від 1 до 31")

Set destSht = ActiveSheet

destSht.Move After:=Worksheets(Worksheets.Count)

origSht.Cells.Copy Destination:=destSht.Cells

Exit Sub

eHandle:

MsgBox "Така дата існує - введіть іншу"

Set origSht = Nothing

Set destSht = Nothing

End Sub

Евгений 18.01.2021 в 16:38

Я добавил код перемещения нового листа относительно исходного листа с именем текущего месяца и удаления ненужного нового листа, который создается при повторном вводе одного и того же числа:

Sub NewSheet()

Dim origSht As Worksheet

Dim destSht As Worksheet

On Error GoTo eHandle

Set origSht = ActiveSheet

Sheets.Add.Name = InputBox("Ввести дату - від 1 до 31")

Set destSht = ActiveSheet

If CByte(destSht.Name) = 1 Then

destSht.Move After:=origSht

Else

destSht.Move After:=Worksheets(CStr(CByte(destSht.Name) - 1))

End If

origSht.Cells.Copy Destination:=destSht.Cells

Exit Sub

eHandle:

MsgBox "Така дата існує - введіть іншу"

ActiveSheet.Delete

Set origSht = Nothing

Set destSht = Nothing

End Sub

Эдуард 18.01.2021 в 16:53

Евгений огромное спасибо это то что и требовалось весьма признателен за Вашу помощь!!!

Евгений 18.01.2021 в 18:29

Эдуард, представленный выше код будет работать только с одним месяцем. Excel не даст создать в одной книге несколько листов с одним именем (одно и то же число, но разных месяцев). Вам придется как-то изменить наименование листов, например: 1.01-31.01, 1.02-28.02. Тогда для перемещения новых листов придется использовать другой алгоритм или по окончании одного месяца, все его листы переименовать, например так:

Sub Primer()

Dim d As String, mySheet As Worksheet

d = InputBox("Ввести порядковый номер месяца")

On Error GoTo eHandle

For Each mySheet In ThisWorkbook.Sheets

If IsNumeric(mySheet.Name) Then

mySheet.Name = mySheet.Name & "." & d

End If

Exit Sub

eHandle:

MsgBox "Такой номер уже используется - введите другой"

End Sub

Эдуард 18.01.2021 в 20:42

Я понял этого и не требуется по окончанию месяца листы будут сохранены отдельно.
А вот по предедущему коду нельзя ввести произвольное число т.е не по порядку 1,2,3 а сразу например 17 пропустив с 1 по 16?
1. Евгений 18.01.2021 в 22:40
  
  Можно и так, если указать имя листа, перед которым вставлять перемещаемый (вместо всего блока If … End If):
  
  1
  
  destSht.Move Before:=Worksheets("Февраль")

Эдуард 19.01.2021 в 09:08

Sub NewSheet()

Dim origSht As Worksheet

Dim destSht As Worksheet

On Error GoTo eHandle

Set origSht = ActiveSheet

Sheets.Add.Name = InputBox("Ввести дату - від 1 до 31")

Set destSht = ActiveSheet

destSht.Move Before:=Worksheets("Лютий")

origSht.Cells.Copy Destination:=destSht.Cells

Exit Sub

eHandle:

MsgBox "Така дата існує - введіть іншу"

ActiveSheet.Delete

Set origSht = Nothing

Set destSht = Nothing

End Sub

В таком виде все работает как задумывалось — может кому то пригодится. Спасибо огромное Евгению за помощь!

Эдуард 21.01.2021 в 17:32

Помогите с мелочью никак не пойму куда вставить умножить на 2,1 и на 1,9 чтобы не считалось +_ 20% в этой формуле?
=ДВССЫЛ(АДРЕС(СТРОКА();СТОЛБЕЦ()-1;1;1))
1. Евгений 21.01.2021 в 20:02
  
  Эдуард, может быть у вас для ячейки с формулой установлен формат «Процентный»?
Эдуард 21.01.2021 в 20:21

Нет числовой. условное форматирование со стрелками вверх вниз и вправо
=ДВССЫЛ(АДРЕС(СТРОКА();СТОЛБЕЦ()-1;1;1*2,6)) для стрелки вверх
=ДВССЫЛ(АДРЕС(СТРОКА();СТОЛБЕЦ()-1;1;1*2,4)) для стрелки вправо
но не работает может я не туда вставляю *2,6
1. Евгений 21.01.2021 в 21:52
  
  Синтаксис функции АДРЕС:
  АДРЕС(номер_строки;номер_столбца;[тип_ссылки];[A1];[имя_листа])
  Там, где вы умножаете, должно быть логическое значение [A1]: ИСТИНА или ЛОЖЬ (1 или 0).
Александр 30.05.2021 в 11:28

Ребята привет! Подскажите как решить (буду очень признателен за готовый код) проблему.
Есть Гугл таблица с 10 листами. Один лист требуется скачивать на комп в формате CSV — это легко делается самой таблицей — есть возможность сохранить текущий лист. А вот второй лист нужно скачивать в формате ексель. И гугл уже не позволяет скачать текущий лист. Он скачивает в формате ексель всю книгу целиком. Это не удобно. Приходится удалять вручную ненужные листы. Либо сначала копировать весь лист в гугле, а затем вставлять в лист екселя.
В общем нужен код, который в дальнейшем привяжу к кнопочке, для скачивания определенного листа из книги с данными без формул и в формате ексель.
0mega 20.09.2021 в 14:37

удаляю Лист по имени на ярлычке

1

Worksheets("Лист1").Delete

машина вступает в диалог:
» Выбранные Листы будут удалены безвозвратно…»
Как сделать чтобы машина удаляла и не спрашивала
1. Евгений 20.09.2021 в 19:51
  
  1
  2
  3
  
  Application.DisplayAlerts = False
  Worksheets("Лист1").Delete
  Application.DisplayAlerts = True
2. 1. Александр 24.09.2021 в 10:50
    
    Евгений, помогите пожалуйста со следующей задачей.
    В папке несколько документов эксель, в каждом из которых несколько листов.
    Необходимо, чтобы макрос открывал по порядку каждый документ, проходил по каждому листу и брал оттуда нужную информацию. Затем эта информация переносится в новый документ эксель в заданном порядке.
    В целом программу я реализовал, но столкнулся с проблемой, что debug упирается в последний лист первого открытого документа и не может дальше перейти к следующему документу. Т.е. необходимо прописать условие, чтобы vba понимал, что данный лист в документе последний.
    Подскажите пожалуйста, как это сделать?
  2. 1. Евгений 24.09.2021 в 11:57
      
      Александр, для обхода листов каждой книги используйте цикл For Each… Next:
      
      1
      2
      3
      4
      
      Dim mySheet As Worksheet, myWorkbook As Workbook
          For Each mySheet In myWorkbook.Sheets
              --------------------------------
          Next
      
      Цикл будет завершен после обработки последнего листа.
Сбитый Лётчик Небосводов 02.11.2021 в 10:59

Здравствуйте!
Возможно ли при копировании листа из другого файла перенести и пользовательский стиль таблицы?

Евгений 02.11.2021 в 11:45

Добрый день!
Если не ошибаюсь, пользовательский стиль таблицы всегда копируется вместе с листом, но внешний вид таблиц будет одинаков, если оба файла созданы и открыты в одной версии Excel.

Сбитый Лётчик Небосводов 02.11.2021 в 13:32

Спасибо за ответ.
Увы, не так, и даже всё не так.
Стиль «пытается» копироваться, цвета отличаются оттенками, но это полбеды. Главное, что нужно мне, чтобы копировался цвет шрифта таблицы, а этого не происходит. Почему-то на листе-цели устанавливается на весь лист чёрный шрифт, который Эксель считает главнее табличного.
И даже больше. После ручной замены на всё листе-цели шрифта с чёрного на авто замены цвета шрифта в импортированной таблице не происходит. Что всегда есть при ручной работе с таблицами.
Ну, и совсем глюк. Пользовательский стиль переезжает и доступен в новой книге. Но даже при ручном его выборе на листе-цели для таблицы не происходит смены цвета шрифта.
Цвет можно поменять только руками (макросом) без учёта таблицы.
Всё это происходит на одном компьютере в одной ОС В10.

Евгений 02.11.2021 в 18:16

Я провел тест: создал умную таблицу, создал пользовательский стиль и применил его к таблице. Далее изменил у разных блоков строк цвет шрифта и начертание (полужирное, курсив). Программно скопировал лист с таблицей в другую книгу. Все форматирование сохранилось и пользовательский стиль тоже появился в разделе со стилями таблиц. У меня версия Excel — 16.0 (Excel 2016). Оба файла должны быть созданы в одной версии Excel, так как более старые версии Excel могут не поддерживать возможности новых версий.

Сбитый Лётчик Небосводов 02.11.2021 в 18:26

Хм. Эксель 2016, всё выше описанное по-прежнему.
Если не затруднит, скопируйте умную таблицу макросом на новый лист, перед этим созданный тем же макросом.

Сбитый Лётчик Небосводов 02.11.2021 в 18:29

На новый лист в другом файле для чистоты эксперимента.

Евгений 02.11.2021 в 22:33

Скопировал этим кодом:

Sub Primer1()

Dim myWSh As Worksheet

Set myWSh = Workbooks("Книга2.xlsx").Worksheets.Add

Workbooks("Книга1.xlsm").Worksheets("Лист6").Range("A1:E19").Copy _

myWSh.Range("A1:E19")

End Sub

Все форматы и стили скопировались, кроме ширины столбцов.

Сбитый Лётчик Небосводов 04.11.2021 в 16:51

Евгений, спасибо за ответ.
Ваш код не работает в новом файле (Subscript out of range). Но дело не в этом.
Прм ручном копировании таблицы в новый файл происходит «Стиль «пытается» копироваться, цвета отличаются оттенками, но это полбеды. Главное, что нужно мне, чтобы копировался цвет шрифта таблицы, а этого не происходит». При установке цвета шрифтов на странице на авто, цвета шрифтов таблицы становятся верными, как в оригинале.
А при копировании макросом всё по-прежнему, цвет шрифта не поменять никак.

Сбитый Лётчик Небосводов 04.11.2021 в 17:41

Sub Primer1()

Workbooks("Книга.xlsm").Worksheets("Лист1").Range("B7:I11").Copy

Workbooks.Add

ActiveSheet.Paste Range("C8")

End Sub

Переносит стиль (фоны похожие, цвет шрифта совпадает), кроме ширин столбцов.
Евгений, спасибо.
Почему у меня не работает в большом макросе и не работает при ручной переноске придётся списать на тёмные силы электричества.

1. Сбитый Лётчик Небосводов 04.11.2021 в 18:01
  
  Тёмные силы электричества = глюк Экселя.
  Утверждаю, что пользовательские настройки умной таблицы не переносятся полностью ни макросом, ни руками. В предыдущем сообщении переносились из уже до этого руками перенесённой умной таблицы, и при переносе Эксель подобрал похожие фоны, а я руками поправил цвет шрифтов на авто. А если взять свою раскрашенную умную таблицу как шаблон для переноса, то ни точных фонов, ни цветов шрифтов.

Влад 19.11.2021 в 02:05

Здравствуйте, подскажите, пожалуйста, как сделать так, чтобы листы добавлялись по порядку т.е. начиная с первого после ранее удаленных листов. У меня есть задание: «Создать новые листы количеством 22 перед первым листом с именем варианта. Скопировать на лист 21 таблицу с исходной информацией и сгенерированными данными»
Однако при этом мне нужно сделать так, чтобы процедура могла запускаться многократно. Когда я удалил первые добавленные 22 листа и добавил новые, нумерация пошла с 23-его, а не с 1-го, и соответственно, я уже не могу переместить информацию на 21 лист. Заранее благодарен за ответ.
0mega 26.01.2022 в 13:49

Евгений здравствуйте

1
2
3
4

Sub Test()
Sheets.Add.Name = "NewSheet"
Sheets("NewSheet").Move After:=Sheets(8)
End Sub

Здесь «8» — прописываю руками
руками не хочу.
машина должна сама посчитать кол-во листов и вставить в конец списка
1. Евгений 26.01.2022 в 14:10
  
  Добрый день!
  
  1
  2
  3
  4
  
  Sub Test()
  Sheets.Add.Name = "NewSheet"
  Sheets("NewSheet").Move After:=Sheets(Sheets.Count)
  End Sub
2. 1. 0mega 26.01.2022 в 14:22
    
    спасибо работает
Иван 10.03.2022 в 15:01

Здравствуйте, может подскажете, нужно, чтобы макрос при каждом запуске создавал копию листа и присваивал ему имя равное СЕГОДНЯ(). (имя листа дата). А в случае если такой лист существует то старый лист меняется на новый. у Эдуарда очень похоже, но разобрать не могу. Спасибо

Евгений 12.03.2022 в 11:10

Добрый день, Иван!
Надеюсь, этот код вам подойдет:

Sub Primer()

Application.DisplayAlerts = False

Dim mySheet As Worksheet

For Each mySheet In Worksheets

If mySheet.Name = Date Then mySheet.Delete: Exit For

Worksheets("Лист1").Copy After:=Sheets(Sheets.Count)

ActiveSheet.Name = Date

Application.DisplayAlerts = True

End Sub

1. Иван 12.03.2022 в 15:31
  
  Спасибо большое! То что нужно!
  Может подскажете, в какой статье поискать как в мой вновь созданный лист вставить данные из другой Книги, при чем эту книгу тоже надо найти (сводка 01.03.2022, сводка 02.03.2022). Спасибо!

Алексей 09.04.2022 в 10:37

Здравствуйте, Евгений. А можно сделать макрос который при открытии документа эксель из него удаляет определённые листы?
1. Евгений 09.04.2022 в 11:39
  
  Здравствуйте, Алексей!
  Создайте в модуле книги процедуру Workbook_Open и поместите в нее код удаления листов:
  
  1
  2
  3
  
  Private Sub Workbook_Open()
  'Код удаления листов
  End Sub

Обсуждение закрыто.