VBA Excel. Оператор If…Then…Else и функция IIf

Однострочная и многострочная конструкции оператора If…Then…Else и функция IIf, используемые в коде VBA Excel — синтаксис, компоненты, примеры.

Содержание

Оператор If…Then…Else

Оператор If…Then…Else предназначен для передачи управления одному из блоков операторов в зависимости от результатов проверяемых условий.

Однострочная конструкция

Оператор If…Then…Else может использоваться в однострочной конструкции без ключевых слов Else, End If.

Синтаксис однострочной конструкции If…Then…

1	If [условие] Then [операторы]

Компоненты однострочной конструкции If…Then…

условие — числовое или строковое выражение, возвращающее логическое значение True или False;
операторы — блок операторов кода VBA Excel, который выполняется, если компонент условие возвращает значение True.

Если компонент условие возвращает значение False, блок операторов конструкции If…Then… пропускается и управление программой передается следующей строке кода.

Пример 1

Sub Primer1()

Dim d As Integer, a As String

d = InputBox("Введите число от 1 до 20", "Пример 1", 1)

If d > 10 Then a = "Число " & d & " больше 10"

MsgBox a

End Sub

Многострочная конструкция

Синтаксис многострочной конструкции If…Then…Else

If [условие] Then

[операторы]

ElseIf [условие] Then

[операторы]

----------------

Else

[операторы]

End If

Компоненты многострочной конструкции If…Then…Else:

условие — числовое или строковое выражение, следующее за ключевым словом If или ElseIf и возвращающее логическое значение True или False;
операторы — блок операторов кода VBA Excel, который выполняется, если компонент условие возвращает значение True;
пунктирная линия обозначает дополнительные структурные блоки из строки ElseIf [условие] Then и строки [операторы].

Если компонент условие возвращает значение False, следующий за ним блок операторов конструкции If…Then…Else пропускается и управление программой передается следующей строке кода.

Самый простой вариант многострочной конструкции If…Then…Else:

If [условие] Then

[операторы]

Else

[операторы]

End If

Пример 2

Sub Primer2()

Dim d As Integer, a As String

d = InputBox("Введите число от 1 до 40", "Пример 2", 1)

If d < 11 Then

a = "Число " & d & " входит в первую десятку"

ElseIf d > 10 And d < 21 Then

a = "Число " & d & " входит во вторую десятку"

ElseIf d > 20 And d < 31 Then

a = "Число " & d & " входит в третью десятку"

Else

a = "Число " & d & " входит в четвертую десятку"

End If

MsgBox a

End Sub

Функция IIf

Функция IIf проверяет заданное условие и возвращает значение в зависимости от результата проверки.

Синтаксис функции

1	IIf([условие], [если True], [если False])

Компоненты функции IIf

условие — числовое или строковое выражение, возвращающее логическое значение True или False;
если True — значение, которое возвращает функция IIf, если условие возвратило значение True;
если False — значение, которое возвращает функция IIf, если условие возвратило значение False.

Компоненты если True и если False могут быть выражениями, значения которых будут вычислены и возвращены.

Пример 3

Sub Primer3()

Dim d As Integer, a As String

Instruk:

On Error Resume Next

d = InputBox("Введите число от 1 до 20 и нажмите OK", "Пример 3", 1)

If d > 20 Then GoTo Instruk

a = IIf(d < 10, d & " - число однозначное", d & " - число двузначное")

MsgBox a

End Sub

Пример 4
Стоит отметить, что не зависимо от того, выполняется условие или нет, функция IIf вычислит оба выражения в параметрах если True и если False:

Sub Primer4()

On Error GoTo Instruk

Dim x, y

x = 10

y = 5

MsgBox IIf(x = 10, x + 5, y + 10)

MsgBox IIf(x = 10, x + 5, y / 0)

Exit Sub

Instruk:

MsgBox "Произошла ошибка: " & Err.Description

End Sub

При нажатии кнопки «Cancel» или закрытии крестиком диалогового окна InputBox из первых двух примеров, генерируется ошибка, так как в этих случаях функция InputBox возвращает пустую строку. Присвоение пустой строки переменной d типа Integer вызывает ошибку. При нажатии кнопки «OK» диалогового окна, числа, вписанные в поле ввода в текстовом формате, VBA Excel автоматически преобразует в числовой формат переменной d. В третьем примере есть обработчик ошибок.

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

23 комментария для “VBA Excel. Оператор If…Then…Else и функция IIf”

Александр 08.02.2019 в 11:47

при ElseIf после Then выражение должно быть обязательно с новой строки

Евгений 08.02.2019 в 13:28

Спасибо, Александр!
Я изменил некоторые формулировки в статье, допускающие неоднозначное толкование. Кроме того, я решил проверить, что будет, если поместить при ElseIf выражение после Then, и вот что получилось:

Sub primer2()

Dim d As Integer, a As String

d = InputBox("Введите число от 1 до 40", "Пример 2", 1)

If d < 11 Then

a = "Число " & d & " входит в первую десятку"

ElseIf d > 10 And d < 21 Then a = "Число " & d & " входит во вторую десятку"

ElseIf d > 20 And d < 31 Then a = "Число " & d & " входит в третью десятку"

Else: a = "Число " & d & " входит в четвертую десятку"

End If

MsgBox a

End Sub

Код работает! Но он не будет работать, если строки

1 2	If d < 11 Then a = "Число " & d & " входит в первую десятку"

заменить на строку

1	If d < 11 Then a = "Число " & d & " входит в первую десятку"

или на строку

1	If d < 11 Then: a = "Число " & d & " входит в первую десятку"

Михаил 23.07.2019 в 09:37

Конструкция:
if (condition)
then (action 1)
else (action 2)
Допустим, condition = true. Следовательно, выполняется action 1. Но затем операции, совершенные в action 1, приводят к тому, что условие уже не соблюдается, т.е. после завершения action 1 condition = false. Означает ли это, что сработает также конструкция else и будут выполняться операции action 2? Или условие всей конструкции if-then-else проверяется в один момент времени и не подвержено влиянию операций внутри конструкции?
1. Евгений 23.07.2019 в 10:44
  
  Привет, Михаил!
  Условие в вашей конструкции проверяется один раз:
  
  1
  2
  3
  4
  5
  6
  7
  8
  9
  10
  
  Sub Test1()
  Dim x As Integer
  x = 1
    If x < 3 Then
      x = 5
    Else
      x = 10
    End If
  MsgBox x
  End Sub
  
  И даже если в конструкции используется блок ElseIf ... Then, для проверки условия используется первоначальное значение:
  
  1
  2
  3
  4
  5
  6
  7
  8
  9
  10
  
  Sub Test2()
  Dim x As Integer
  x = 1
    If x < 3 Then
      x = 5
    ElseIf x > 3 Then
      x = 10
  End If
  MsgBox x
  End Sub
  
  В обоих случаях MsgBox выведет число 5.
Виктор 25.12.2019 в 17:48

чем отличается однострочная и многострочная форма синтаксиса

Евгений 25.12.2019 в 19:07

Привет, Виктор!
Однострочная запись короче и работает только с одним условием.

Сбитый Лётчик Небосводов 15.01.2022 в 17:40

Здравствуйте, Евгений!
Однострочная запись работает не только с одним условием.

Евгений 15.01.2022 в 18:50

Добрый вечер!
Здесь «одно условие» означает выражение, которое может состоять из нескольких входящий в него условий (лучше сказать «под-условий») и возвращает логическое значение True или False. Такое выражение может быть только одно в однострочной записи.

Sub Test()

Dim x, y, z

x = 10: y = 16: z = 50

If x > 0 And y = 16 And z < 100 Then MsgBox "Условие выполнено": Exit Sub

MsgBox "Условие не выполнено"

End Sub

Второе условие расположено в многострочной записи после ключевого слова Then и операторов, выполняемых при истинном значении первого условия, и предваряется ключевым словом ElseIf.

Сбитый Лётчик Небосводов 16.01.2022 в 00:52

Здравствуйте, Евгений!
Может знаете, что быстрее

1	If Условие1 And If Условие2 And If Условие3 … And If УсловиеМакс Then

или

If Условие1 Then

If Условие2 Then

If Условие3 Then …

If УсловиеМакс Then

1. Евгений 16.01.2022 в 01:49
  
  Не знаю, не сравнивал. Измерьте скорость выполнения обоих вариантов с помощью функции MicroTimer.
Сбитый Лётчик Небосводов 06.07.2022 в 18:27

Здравствуйте, Евгений!
Продолжим спор 🙂
Однострочная запись работает не только с одним условием.

1
2
3

Dim t$
If t <> "a" Then If t <> "b" Then t = "c"
MsgBox t

P.S. Удалите мои сообщения, которые нужно удалить.
1. Евгений 07.07.2022 в 21:21
  
  Привет!
  Я и не думал, что такое возможно! Добавил Else — тоже работает:
  
  1
  2
  3
  4
  5
  6
  
  Sub Primer()
  Dim t$
  t = "b"
  If t <> "a" Then If t <> "b" Then t = "c" Else t = "d"
  MsgBox t
  End Sub
  
  Видимо, незадокументированные возможности однострочной функции If.

Икром 18.01.2022 в 20:15

Решить с помощью VBA
Определите, является ли заданное целое число А нечётным двузначным
числом.

Евгений 18.01.2022 в 22:01

Привет, Икром!
Решение может быть таким:

Sub Primer()

Dim A

A = InputBox("Введите целое число")

If Not IsNumeric(A) Then Exit Sub

If Len(A) = 2 And CLng(A) Mod 2 > 0 Then

MsgBox "Заданное целое число является нечетным двузначным"

Else

MsgBox "Заданное целое число не является нечетным двузначным"

End If

End Sub

Сбитый Лётчик Небосводов 14.02.2022 в 05:30

Здравствуйте!
«блок операторов после ключевого слова Else выполняется в любом случае, но структурный блок кода из строки Else и строки [операторы] не является обязательным и может быть пропущен».
Это только у меня вызывает недоумение?
«блок операторов после ключевого слова Else выполняется в любом случае»?! Да ну!
И то, что после «но» вовсе не противоречит первой части, хотя при употреблении «но» должно бы.
А по смыслу вторая это «после но» д.б. в отдельном предложении, даже в отдельном абзаце.
1. Евгений 14.02.2022 в 13:02
  
  Добрый день!
  Согласен. Это выражение касается функции IIf. Исправил. Спасибо за бдительность!
Павел 01.03.2022 в 00:20

Есть столбик с процентами выполнения плана. Если больше 70%,то цвет текста зеленый, если меньше 40% то цвет текста красный. Как это прописать у меня получается только покрасить весь столбец в красный. Помогите пожалуйста я всю голову словмал что не так.

Евгений 01.03.2022 в 02:22

Павел, если в ячейке с процентным форматом отображается 90%, то фактически в ней содержится число 0,9. Вам надо сравнивать значения ячеек не с 70 и 40, а с 0,7 и 0,4.

Павел 01.03.2022 в 12:36

Евгений, я так пробовал, но тогда сразу подсвечивается красным вся переменная.

Sub Primer()

Dim myCell As Range

For Each myCell In Range("D4:D29")

If myCell > 0.7 Then

myCell.Font.Color = vbGreen

ElseIf myCell < 0.4 Then

myCell.Font.Color = vbRed

End If

End Sub

И не работает, просто красит весь столбик в красный то есть работает вторая строка, первая с зеленым цветом не работает, он проскакивает её.

1. Евгений 01.03.2022 в 15:32
  
  Павел, я исправил код в вашем комментарии. Пробуйте снова.

Айжан 18.04.2022 в 13:31

Добрый день!
Во втором примере получается все цифры от 31 до бесконечности в четвертом десятке (хотя диапазон от 1 до 40). Может стоит дописать как в третьем примере, чтобы при несоответствии цифры возвращал на начальное окно ввода?
Егор 22.06.2022 в 16:43

Как написать код, чтобы при закрашивании ячейки красным цветом открывалась почта аутлук?
1. Евгений 23.06.2022 в 12:25
  
  Добрый день, Егор!
  В VBA Excel нет события рабочего листа, привязанного к смене цвета ячейки.

Обсуждение закрыто.