VBA Excel. Функции для работы с датой и временем

Функции для работы с датой и временем в VBA Excel. Синтаксис, параметры, спецсимволы, примеры. Функции, возвращающие текущие дату и время по системному таймеру.

Содержание

1. Функция Date

2. Функция DateAdd

3. Функция DateDiff

4. Функция DatePart

5. Функция DateSerial

12. Функция MonthName

13. Функция Now

14. Функция Second

15. Функция Time

16. Функция TimeSerial

17. Функция TimeValue

18. Функция Weekday

19. Функция WeekdayName

Функция Date

Date – это функция, которая возвращает значение текущей системной даты. Тип возвращаемого значения – Variant/Date.

Синтаксис

Date

Пример

Sub PrimerDate()

MsgBox "Сегодня: " & Date

End Sub

Функция DateAdd

DateAdd – это функция, которая возвращает результат прибавления к дате указанного интервала времени. Тип возвращаемого значения – Variant/Date.

Синтаксис

1	DateAdd(interval, number, date)

Параметры

Параметр	Описание
interval	Обязательный параметр. Строковое выражение из спецсимволов, представляющее интервал времени, который требуется добавить.
number	Обязательный параметр. Числовое выражение, задающее количество интервалов, которые необходимо добавить. Может быть как положительным (возвращается будущая дата), так и отрицательным (возвращается предыдущая дата).
date	Обязательный параметр. Значение типа `Variant/Date` или литерал, представляющий дату, к которой должен быть добавлен интервал.

Таблицу аргументов (значений) параметра interval смотрите в параграфе «Приложение 1».

Примечание к таблице аргументов: три символа – y, d, w – указывают функции DateAdd на один день, который необходимо прибавить к исходной дате number раз.

Пример

Sub PrimerDateAdd()

MsgBox "31.01.2021 + 1 месяц = " & DateAdd("m", 1, "31.01.2021") 'Результат: 28.02.2021

MsgBox "Сегодня + 3 года = " & DateAdd("yyyy", 3, Date)

MsgBox "Сегодня - 2 недели = " & DateAdd("ww", -2, Date)

MsgBox "10:22:14 + 10 минут = " & DateAdd("n", 10, "10:22:14") 'Результат: 10:32:14

End Sub

Функция DateDiff

DateDiff – это функция, которая возвращает количество указанных интервалов времени между двумя датами. Тип возвращаемого значения – Variant/Long.

Синтаксис

1	DateDiff(interval, date1, date2, [firstdayofweek], [firstweekofyear])

Параметры

Параметр	Описание
interval	Обязательный параметр. Строковое выражение из спецсимволов, представляющее интервал времени, количество которых (интервалов) требуется вычислить между двумя датами.
date1, date2	Обязательные параметры. Значения типа `Variant/Date`, представляющие две даты, между которыми вычисляется количество указанных интервалов.
firstdayofweek	Необязательный параметр. Константа, задающая первый день недели. По умолчанию – воскресенье.
firstweekofyear	Необязательный параметр. Константа, задающая первую неделю года. По умолчанию – неделя, в которую входит 1 января.

Таблицу аргументов (значений) параметра interval смотрите в параграфе «Приложение 1».

Примечание к таблице аргументов: в отличие от функции DateAdd, в функции DateDiff спецсимвол "w", как и "ww", обозначает неделю. Но расчет осуществляется по разному. Подробнее об этом на сайте разработчиков.

Параметры firstdayofweek и firstweekofyear определяют правила расчета количества недель между датами.

Таблицы констант из коллекций firstdayofweek и firstweekofyear смотрите в параграфах «Приложение 2» и «Приложение 3».

Пример

Sub PrimerDateDiff()

'Даже если между датами соседних лет разница 1 день,

'DateDiff с интервалом "y" покажет разницу - 1 год

MsgBox DateDiff("y", "31.12.2020", "01.01.2021") 'Результат: 1 год

MsgBox DateDiff("d", "31.12.2020", "01.01.2021") 'Результат: 1 день

MsgBox DateDiff("n", "31.12.2020", "01.01.2021") 'Результат: 1440 минут

MsgBox "Полных лет с начала века = " & DateDiff("y", "2000", Year(Now) - 1)

End Sub

Функция DatePart

DatePart – это функция, которая возвращает указанную часть заданной даты. Тип возвращаемого значения – Variant/Integer.

Есть предупреждение по использованию этой функции.

Синтаксис

1	DatePart(interval, date, [firstdayofweek], [firstweekofyear])

Параметры

Параметр	Описание
interval	Обязательный параметр. Строковое выражение из спецсимволов, представляющее часть даты, которую требуется извлечь.
date	Обязательные параметры. Значение типа `Variant/Date`, представляющее дату, часть которой следует извлечь.
firstdayofweek	Необязательный параметр. Константа, задающая первый день недели. По умолчанию – воскресенье.
firstweekofyear	Необязательный параметр. Константа, задающая первую неделю года. По умолчанию – неделя, в которую входит 1 января.

Таблицу аргументов (значений) параметра interval смотрите в параграфе «Приложение 1». В третьей графе этой таблицы указаны интервалы значений, возвращаемых функцией DatePart.

Таблицы констант из коллекций firstdayofweek и firstweekofyear смотрите в параграфах «Приложение 2» и «Приложение 3».

Пример

Sub PrimerDatePart()

MsgBox DatePart("y", "31.12.2020") 'Результат: 366

MsgBox DatePart("yyyy", CDate(43685)) 'Результат: 2019

MsgBox DatePart("n", CDate(43685.45345)) 'Результат: 52

MsgBox "День недели по счету сегодня = " & DatePart("w", Now, vbMonday)

End Sub

Функция DateSerial

DateSerial – это функция, которая возвращает значение даты для указанного года, месяца и дня. Тип возвращаемого значения – Variant/Date.

Синтаксис

1	DateSerial(year, month, day)

Параметры

Параметр	Описание
year	Обязательный параметр типа Integer. Числовое выражение, возвращающее значение от 100 до 9999 включительно.
month	Обязательный параметр типа Integer. Числовое выражение, возвращающее любое значение (в пределах Integer), а не только от 1 до 12.*
day	Обязательный параметр типа Integer. Числовое выражение, возвращающее любое значение (в пределах Integer), а не только от 1 до 31.*

* Функция DateSerial автоматически пересчитывает общее количество дней в полные месяцы и остаток, общее количество месяцев в полные годы и остаток (подробнее в примере).

Пример

Sub PrimerDateSerial()

MsgBox DateSerial(2021, 2, 10) 'Результат: 10.02.2020

MsgBox DateSerial(2020, 1, 400) 'Результат: 03.02.2021

End Sub

Разберем подробнее строку DateSerial(2020, 1, 400):

400 дней = 366 дней + 31 день + 3 дня;
366 дней = 1 год, так как по условию month:=1, значит февраль 2020 входит в расчет, а в нем – 29 дней;
31 день = 1 месяц, так как сначала заполняется январь (по условию month:=1);
3 дня – остаток.

В итоге получается:

DateSerial(2020+1, 1+1, 3) = DateSerial(2021, 2, 3)

Функция DateValue

DateValue – это функция, которая преобразует дату, указанную в виде строки, в значение типа Variant/Date (время игнорируется).

Синтаксис

1	DateValue(date)

Параметр date – строковое выражение, представляющее дату с 1 января 100 года по 31 декабря 9999 года.

Пример

Sub PrimerDateValue()

MsgBox DateValue("8 марта 2021") 'Результат: 08.03.2021

MsgBox DateValue("17 мая 2021 0:59:15") 'Результат: 17.05.2021

End Sub

Функция DateValue игнорирует время, указанное в преобразуемой строке, но если время указано в некорректном виде (например, «10:60:60»), будет сгенерирована ошибка.

Функция Day

Day – это функция, которая возвращает день месяца в виде числа от 1 до 31 включительно. Тип возвращаемого значения – Variant/Integer.

Синтаксис

Day(date)

Параметр date – любое числовое или строковое выражение, представляющее дату.

Пример

Sub PrimerDay()

MsgBox Day(Now)

End Sub

Функция IsDate

IsDate – это функция, которая возвращает True, если выражение является датой или распознается как допустимое значение даты или времени. В остальных случаях возвращается значение False.

Синтаксис

1	IsDate(expression)

Параметр expression – это переменная, возвращающая дату или строковое выражение, распознаваемое как дата или время.

Значение, возвращаемое переменной expression, не должно выходить из диапазона допустимых дат: от 1 января 100 года до 31 декабря 9999 года (для Windows).

Пример

Sub PrimerIsDate()

MsgBox IsDate("18 апреля 2021") 'Результат: True

MsgBox IsDate("31 февраля 2021") 'Результат: False

MsgBox IsDate("4.10.20 11:12:54") 'Результат: True

End Sub

Функция Hour

Hour – это функция, которая возвращает количество часов в виде числа от 0 до 23 включительно. Тип возвращаемого значения – Variant/Integer.

Синтаксис

1	Hour(time)

Параметр time – любое числовое или строковое выражение, представляющее время.

Пример

Sub PrimerHour()

MsgBox Hour(Now)

MsgBox Hour("22:36:54")

End Sub

Функция Minute

Minute – это функция, которая возвращает количество минут в виде числа от 0 до 59 включительно. Тип возвращаемого значения – Variant/Integer.

Синтаксис

1	Minute(time)

Параметр time – любое числовое или строковое выражение, представляющее время.

Пример

Sub PrimerMinute()

MsgBox Minute(Now)

MsgBox Minute("22:36:54")

End Sub

Функция Month

Month – это функция, которая возвращает день месяца в виде числа от 1 до 12 включительно. Тип возвращаемого значения – Variant/Integer.

Синтаксис

1	Month(date)

Параметр date – любое числовое или строковое выражение, представляющее дату.

Пример

Sub PrimerMonth()

MsgBox Month(Now)

End Sub

Функция MonthName

MonthName – это функция, которая возвращает название месяца в виде строки.

Синтаксис

1	MonthName(month, [abbreviate])

Параметры

Параметр	Описание
month	Обязательный параметр. Числовое обозначение месяца от 1 до 12 включительно.
abbreviate	Необязательный параметр. Логическое значение: True – возвращается сокращенное название месяца, False (по умолчанию) – название месяца не сокращается.

Пример

Sub PrimerMonthName()

MsgBox MonthName(10) 'Результат: Октябрь

MsgBox MonthName(10, True) 'Результат: окт

End Sub

Функция Now

Now – это функция, которая возвращает текущую системную дату и время. Тип возвращаемого значения – Variant/Date.

Синтаксис

Now

Пример

Sub PrimerNow()

MsgBox Now

MsgBox Day(Now)

MsgBox Hour(Now)

End Sub

Функция Second

Second – это функция, которая возвращает количество секунд в виде числа от 0 до 59 включительно. Тип возвращаемого значения – Variant/Integer.

Синтаксис

1	Second(time)

Параметр time – любое числовое или строковое выражение, представляющее время.

Пример

Sub PrimerSecond()

MsgBox Second(Now)

MsgBox Second("22:30:14")

End Sub

Функция Time

Time – это функция, которая возвращает значение текущего системного времени. Тип возвращаемого значения – Variant/Date.

Синтаксис

Time

Пример

Sub PrimerTime()

MsgBox "Текущее время: " & Time

End Sub

Функция TimeSerial

TimeSerial – это функция, которая возвращает значение времени для указанного часа, минуты и секунды. Тип возвращаемого значения – Variant/Date.

Синтаксис

1	TimeSerial(hour, minute, second)

Параметры

Параметр	Описание
hour	Обязательный параметр типа Integer. Числовое выражение, возвращающее значение от 0 до 23 включительно.
minute	Обязательный параметр типа Integer. Числовое выражение, возвращающее любое значение (в пределах Integer), а не только от 0 до 59.*
second	Обязательный параметр типа Integer. Числовое выражение, возвращающее любое значение (в пределах Integer), а не только от 0 до 59.*

* Функция TimeSerial автоматически пересчитывает общее количество секунд в полные минуты и остаток, общее количество минут в полные часы и остаток (подробнее в примере).

Пример

Sub PrimerTime()

MsgBox TimeSerial(5, 16, 4) 'Результат: 5:16:04

MsgBox TimeSerial(5, 75, 158) 'Результат: 6:17:38

End Sub

Разберем подробнее строку TimeSerial(5, 75, 158):

158 секунд = 120 секунд (2 минуты) + 38 секунд;
75 минут = 60 минут (1 час) + 15 минут.

В итоге получается:

TimeSerial(5+1, 15+2, 38) = TimeSerial(6, 17, 38)

Функция TimeValue

TimeValue – это функция, которая преобразует время, указанное в виде строки, в значение типа Variant/Date (дата игнорируется).

Синтаксис

1	TimeValue(time)

Параметр time – строковое выражение, представляющее время с 0:00:00 по 23:59:59 включительно.

Пример

Sub PrimerTimeValue()

MsgBox TimeValue("6:45:37 PM") 'Результат: 18:45:37

MsgBox TimeValue("17 мая 2021 3:59:15 AM") 'Результат: 3:59:15

End Sub

Функция TimeValue игнорирует дату, указанную в преобразуемой строке, но если дата указана в некорректном виде (например, «30.02.2021»), будет сгенерирована ошибка.

Функция Weekday

Weekday – это функция, которая возвращает день недели в виде числа от 1 до 7 включительно. Тип возвращаемого значения – Variant/Integer.

Синтаксис

1	Weekday(date, [firstdayofweek])

Параметры

Параметр	Описание
date	Обязательный параметр. Любое выражение (числовое, строковое), отображающее дату.
firstdayofweek	Константа, задающая первый день недели. По умолчанию – воскресенье.

Таблицу констант из коллекции firstdayofweek смотрите в параграфе «Приложение 2».

Пример

Sub PrimerWeekday()

MsgBox Weekday("23 апреля 2021", vbMonday) 'Результат: 5

MsgBox Weekday(202125, vbMonday) 'Результат: 6

End Sub

Функция WeekdayName

WeekdayName – это функция, которая возвращает название дня недели в виде строки.

Синтаксис

1	WeekdayName(weekday, [abbreviate], [firstdayofweek])

Параметры

Параметр	Описание
weekday	Обязательный параметр. Числовое обозначение дня недели от 1 до 7 включительно.
abbreviate	Необязательный параметр. Логическое значение: True – возвращается сокращенное название дня недели, False (по умолчанию) – название дня недели не сокращается.
firstdayofweek	Константа, задающая первый день недели. По умолчанию – воскресенье.

Таблицу констант из коллекции firstdayofweek смотрите в параграфе «Приложение 2».

Пример

Sub PrimerWeekdayName()

MsgBox WeekdayName(3, True, vbMonday) 'Результат: Ср

MsgBox WeekdayName(3, , vbMonday) 'Результат: среда

MsgBox WeekdayName(Weekday(Now, vbMonday), , vbMonday)

End Sub

Функция Year

Year – это функция, которая возвращает номер года в виде числа. Тип возвращаемого значения – Variant/Integer.

Синтаксис

1	Year(date)

Параметр date – любое числовое или строковое выражение, представляющее дату.

Пример

Sub PrimerYear()

MsgBox Year(Now)

End Sub

Приложение 1

Таблица аргументов (значений) параметраinterval для функций DateAdd, DateDiff и DatePart:

Аргумент	Описание	Интервал значений
yyyy	Год	100 – 9999
q	Квартал	1 – 4
m	Месяц	1 – 12
y	День года	1 – 366
d	День месяца	1 – 31
w	День недели	1 – 7
ww	Неделя	1 – 53
h	Часы	0 – 23
n	Минуты	0 – 59
s	Секунды	0 – 59

В третьей графе этой таблицы указаны интервалы значений, возвращаемых функцией DatePart.

Приложение 2

Константы из коллекции firstdayofweek:

Константа	Значение	Описание
vbUseSystem	0	Используются системные настройки
vbSunday	1	Воскресенье (по умолчанию)
vbMonday	2	Понедельник
vbTuesday	3	Вторник
vbWednesday	4	Среда
vbThursday	5	Четверг
vbFriday	6	Пятница
vbSaturday	7	Суббота

Приложение 3

Константы из коллекции firstweekofyear:

Константа	Значение	Описание
vbUseSystem	0	Используются системные настройки.
vbFirstJan1	1	Неделя, в которую входит 1 января (по умолчанию).
vbFirstFourDays	2	Неделя, в которую входит не менее четырех дней нового года.
vbFirstFullWeek	3	Первая полная неделя года.

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

31 комментарий для “VBA Excel. Функции для работы с датой и временем”

1 03.07.2021 в 18:11

Здравствуйте!
А как правильно перевести целое число секунд в сутки:часы:минуты:секунды?
(или хотя бы отобразить через MsgBox)
Т.е. например, перевести 113745 в 1 сутки 7 часов 35 минут 45 секунд
Использую просто деление, но думаю, что наверняка есть более удобный способ
Спасибо!

Евгений 03.07.2021 в 21:54

Добрый вечер!
Мне удалось создать такую конструкцию:

Sub Primer()

Dim cmBut As Variant

cmBut = 113745

cmBut = DateAdd("s", cmBut + 1, "31.12.1999 23:59:59")

cmBut = Day(cmBut) - 1 & " суток " & Hour(cmBut) & " часов " & Minute(cmBut) & " минут " & Second(cmBut) & " секунд"

MsgBox cmBut

End Sub

Работает со значением переменной в интервале от 0 до 2147483646 (max cmBut = max Long — 1).

0mega 19.03.2022 в 17:19

B ячейке D3 записана дата 30.04.1997
как получить числовое значение без года
т.е. мне надо получить дату 30.04.1900
В числовом значении это будет 121
* формульное решение: =ДАТА(0;МЕСЯЦ(D3);ДЕНЬ(D3))
1. Евгений 19.03.2022 в 17:48
  
  DateSerial("1900", Month([D3]), Day([D3]))
0mega 19.03.2022 в 21:08

спасибо
Гоголь 25.03.2022 в 23:52

Здравствуйте!
Дана дата в виде строки в американском формате месяц/день/
год. Нужно переделать ее в русский формат день.месяц.год.
примерное решение — Format(InputBox("Ввод даты", "Ввод", "01/01/2018"), "dd.mm.yyyy")
Татьяна 15.04.2022 в 16:55

Добрый день! Отдаю файл ексель с кодом vba над которым работала пол года руководству. Дополнительные программы для защиты не использую. Код просто под паролем. Возникла идея назначить выполнения макросов до определенной даты. Как вы думаете это хорошая идея? Волнует именно, что руководство «забудет о моей напряженной работе».
1. Евгений 16.04.2022 в 12:16
  
  Здравствуйте, Татьяна!
  Идея очень хорошая, если нет возможности сначала передать демо-вариант с ограниченной функциональностью. Лично мне не приходилось ограничивать работу VBA, но я бы в данной ситуации, как вы и предлагаете, использовал бы ограничение по дате. Возможно, кроме напоминания о необходимости оплаты, я бы еще добавил код, удаляющий один из стандартных модулей. Ограничивающую дату, чтобы не бросалась в глаза, лучше отобразить в виде числа:
  
  1
  
  If Date >= 44667 Then MsgBox "Работу пора оплатить!" '16.04.2022
2. 1. Татьяна 16.04.2022 в 17:40
    
    Евгений, спасибо вам большое☀️
Сбитый Лётчик Небосводов 08.05.2022 в 20:09

Здравствуйте!
«Функция Time – это функция, которая возвращает значение текущей системной даты.»
Наверное, всё же времени.
1. Евгений 08.05.2022 в 21:12
  
  Здравствуйте!
  Согласен, была опечатка.
Максим 10.05.2022 в 14:04

Добрый день!
подскажите пожалуйста, а как перевести Tuesday, March 01 2022 в формат 01.03.2022

Евгений 10.05.2022 в 15:12

Добрый день, Максим!
Для этого есть функция DateSerial. Но есть одна проблемка — в русскоязычной версии Excel с помощью конструкции Month(CDate("1 " & StringMonth)) можно преобразовать в число только месяц строкой на русском языке. Поэтому для перевода названия месяца в число будем использовать словарь:

Sub Test()

Dim myDict As Object, myArr, myYear As Integer, myMonth As Byte, myDay As Byte, s As String

s = "Tuesday, March 01 2022"

Set myDict = CreateObject("Scripting.Dictionary")

myDict.Add "January", 1

myDict.Add "February", 2

myDict.Add "March", 3

myDict.Add "April", 4

myDict.Add "May", 5

myDict.Add "June", 6

myDict.Add "July", 7

myDict.Add "August", 8

myDict.Add "September", 9

myDict.Add "October", 10

myDict.Add "November", 11

myDict.Add "December", 12

myArr = Split(s, " ")

myYear = myArr(3)

myMonth = myDict.Item(myArr(1))

myDay = myArr(2)

MsgBox DateSerial(myYear, myMonth, myDay)

End Sub

1. Максим 12.05.2022 в 14:28
  
  Евгений, благодарю!
  протестировал, работает. но в итоге реализовал через питон.

Алексей 11.06.2022 в 15:26

Здравствуйте, Евгений. Есть старая конструкция кода:

Sub удаление_книги()

If Date > #6/11/2022# Then

Application.DisplayAlerts = False

ThisWorkbook.ChangeFileAccess xlReadOnly

Kill ThisWorkbook.FullName

Application.DisplayAlerts = True

ThisWorkbook.Close 0

End If

End Sub

не могу заставить работать эту строку: If Date > #6/11/2022# Then
оставляю файл с необходимой датой, а строка не работает. Захожу в файл, закрываю… не удаляется.
Принудительно запускаю, тогда только удаляет книгу, автоматически — нет.

Евгений 11.06.2022 в 22:45

Здравствуйте, Алексей!
Попробуйте так:

Private Sub Workbook_Open()

If Date > DateSerial(2022, 6, 10) Then

Application.DisplayAlerts = False

ThisWorkbook.ChangeFileAccess xlReadOnly

Kill ThisWorkbook.FullName

Application.DisplayAlerts = True

ThisWorkbook.Close 0

End If

End Sub

Алексей 13.06.2022 в 10:18

Здравствуйте, Евгений.
Не работает. Такое впечатление, что у меня, библиотека не подключена. Но на сколько я понимаю здесь они не нужны.
1. Евгений 13.06.2022 в 13:12
  
  Добрый день!
  У меня Excel 2016, код работает: книга удаляется, остается только «пустой» экземпляр приложения. Код размещается в модуле книги.
2. 1. Алексей 14.06.2022 в 16:01
    
    Здравствуйте, Евгений. У меня тоже 2016. Ничего не мог сделать (запустить работу макроса) пока не отправил на другой компьютер и оттуда обратно (свой компьютер я и обновлял, и перезагружал). Как пришёл файл заработал присланный и старые пробные версии файлов в которых был установлен этот код. Не знаю, что было.
Георгий 01.12.2022 в 10:45

Здравствуйте, Евгений. Подскажите как получить текущую дату в американском стиле (22.12.01, привык сохранять файлы/папки с таким именем, для удобной сортировки по времени).
MsgBox Year(Now) & "." & Month(Now) & "." & Day(Now) результат 2022.12.1 (как оставить только 22 и добавить 0 к числу?)
1. Евгений 01.12.2022 в 10:52
  
  Добрый день, Георгий!
  MsgBox Format(Now, "YY.MM.DD")
Валерка 31.12.2022 в 15:51

Здравствуйте, у меня немного иная ситуация, как с ней бороться — не знаю )
Может подскажите как текущую системную дату NOW() конвертировать в UNIX?

Нужно для парсера, примерно что-то в таком виде: If tralala < Now() Then

Спасибо! )
1. Валерка 31.12.2022 в 15:59
  
  Спасибо, разобрался )
Виталий 16.01.2023 в 21:05

Добрый день.
Подскажите, как вычислить интервал рабочего времени в минутах между двумя датами с началом и окончанием работы, исключая нерабочее время, выходные, праздники и сокращенные дни.
Спасибо.
1. Евгений 18.01.2023 в 00:09
  
  Здравствуйте, Виталий!
  А где вы собираетесь брать исходные данные для вычисления рабочего времени между двумя датами?
2. Евгений 19.01.2023 в 20:03
  
  Посмотрите такой вариант.
Марина 30.01.2023 в 15:37

Добрый день! есть 2 даты: 30.04.2022 и 31.07.2022. Нужно сравнить месяц и год (т.е 04.2022 07.2022). Как правильно записать?

Марина 30.01.2023 в 15:44

(т.е. 04.2022 07.2022)

Евгений 30.01.2023 в 20:31

Здравствуйте, Марина!
Вот два варианта извлечения месяца и года из даты:

Sub Primer()

Dim d1 As Date, d2 As Date

d1 = CDate("30.04.2022")

d2 = CDate("31.07.2022")

Debug.Print Format(d1, "mm.yyyy")

Debug.Print Format(d2, "mm.yyyy")

'или так

Debug.Print Right("30.04.2022", 7)

Debug.Print Right("31.07.2022", 7)

End Sub

Мария 19.04.2023 в 18:02

Добрый день, подскажите, как сделать, чтобы после обновления макроса в конкретной ячейке на листе прописывалось время его обновления?
1. Евгений 19.04.2023 в 20:26
  
  Здравствуйте, Мария!
  Вставьте эту строку в ваш макрос перед End Sub:
  
  1
  
  Sheets("Лист1").Range("A1") = "Время последнего запуска макроса: " & Format(Now(), "hh:mm:ss")

Обсуждение закрыто.