VBA Excel. Функции преобразования типов

Функции преобразования типов данных в VBA Excel. Наименования функций, синтаксис, типы возвращаемых данных, диапазоны допустимых значений выражения-аргумента.

Содержание

Синтаксис функций преобразования

1	Функция(Выражение)

Выражение (аргумент) – это любое строковое или числовое выражение, возвращающее значение, входящее в диапазон допустимых значений для аргумента. Выражение может быть представлено переменной или другой функцией.

Если аргумент, переданный в функцию, не входит в диапазон типа, в который преобразуются данные, происходит ошибка.

Функции преобразования типов

Наименования функций преобразования типов, типы возвращаемых данных, диапазоны допустимых значений для аргумента:

Функция	Тип данных	Диапазон значений аргумента
CBool	Boolean	Любое допустимое строковое или числовое выражение.
CByte	Byte	От 0 до 255.
CCur	Currency	От -922 337 203 685 477,5808 до 922 337 203 685 477,5807.
CDate	Date	Любое допустимое выражение даты.
CDbl	Double	От -1,79769313486231E308 до -4,94065645841247E-324 для отрицательных значений; от 4,94065645841247E-324 до 1,79769313486232E308 для положительных значений.
CDec	Decimal	79 228 162 514 264 337 593 543 950 335 для чисел без десятичных знаков. Для чисел с 28 десятичными знаками диапазон составляет 7,9228162514264337593543950335. Наименьшим возможным числом, отличным от нуля, является число 0,0000000000000000000000000001.
CInt	Integer	От -32 768 до 32 767, дробная часть округляется.
CLng	Long	От -2 147 483 648 до 2 147 483 647, дробная часть округляется.
CSng	Single	От -3,402823E38 до -1,401298E-45 для отрицательных значений; от 1,401298E-45 до 3,402823E38 для положительных значений.
CStr	String	Результат, возвращаемый функцией CStr, зависит от аргумента Выражение.
CVar	Variant	Диапазон совпадает с типом Double для числовых значений и с типом String для нечисловых значений.

Дополнительно для VBA7:

Функция	Тип данных	Диапазон значений аргумента
CLngLng	LongLong	От -9 223 372 036 854 775 808 до 9 223 372 036 854 775 807, дробная часть округляется. Действительно только для 64-разрядных платформ.
CLngPtr	LongPtr	От -2 147 483 648 до 2 147 483 647 для 32-разрядных платформ, от -9 223 372 036 854 775 808 до 9 223 372 036 854 775 807 для 64-разрядных платформ, дробная часть округляется в обоих типах систем.

Примеры преобразования типов

Функция CBool

Функция CBool используется для преобразования выражений в тип данных Boolean.

Dim a

a = CBool(10) 'Результат: True

a = CBool(0) 'Результат: False

a = CBool("True") 'Результат: True

a = CBool("Test") 'Результат: Error

Dim a, b, c

a = "Test1"

b = "Test2"

c = CBool(a = b) 'Результат: False

c = CBool(a <> b) 'Результат: True

Функция CByte

Функция CByte используется для преобразования выражений в тип данных Byte.

Dim a, b, c

a = 654

b = 3.36

c = a / b 'Результат: 194,642857142857

c = CByte(c) 'Результат: 195

c = a * b 'Результат: 2197,44

c = CByte(c) 'Результат: Error

Функция CCur

Функция CCur используется для преобразования выражений в тип данных Currency.

Dim a, b, c

a = 254.6598254

b = 569.2156843

c = a + b 'Результат: 823,8755097

c = CCur(a + b) 'Результат: 823,8755

Функция CDate

Функция CDate используется для преобразования выражений в тип данных Date. Она распознает форматы даты в соответствии с национальной настройкой системы.

Dim a As String, b As Date, c As Double

a = "28.01.2021"

b = CDate(a) 'Результат: #28.01.2021#

c = CDbl(b) 'Результат: 44224

Dim a

a = CDate(44298.63895) 'Результат: #12.04.2021 15:20:05#

a = CDate(44298) 'Результат: #12.04.2021#

a = CDate(0.63895) 'Результат: #15:20:05#

Функция CDbl

Функция CDbl используется для преобразования выражений в тип данных Double.

Dim a As String, b As String, c As Double

a = "45,3695423"

b = "548955,756"

c = CDbl(a) + CDbl(b) 'Результат: 549001,1255423

Примечание
Eсли основной язык системы – русский, при записи в редакторе VBA Excel дробного числа в виде текста, ставим в качестве разделителя десятичных разрядов – запятую. Проверьте разделитель по умолчанию для своей национальной системы:
MsgBox Application.DecimalSeparator

Функция CDec

Функция CDec используется для преобразования выражений в тип данных Decimal.

Dim a As String, b As Double, c

a = "5,9228162514264337593543950335"

b = 5.92281625142643

c = CDec(a) - CDec(b) 'Результат: 0,0000000000000037593543950335

Dim a As Double, b As String, c

a = 4.2643E-14

b = CStr(a) 'Результат: "4,2643E-14"

c = CDec(a) 'Результат: 0,000000000000042643

Функция CInt

Функция CInt используется для преобразования выражений в тип данных Integer.

Dim a As String, b As Integer

a = "2355,9228"

b = CInt(a) 'Результат: 2356

Функция CLng

Функция CLng используется для преобразования выражений в тип данных Long.

Dim a As Date, b As Long

a = CDate(44298.63895) 'Результат: #12.04.2021 15:20:05#

b = CLng(a) 'Результат: 44299

a = CDate(b) 'Результат: #13.04.2021#

Функция CSng

Функция CSng используется для преобразования выражений в тип данных Single.

Dim a As String, b As Single

a = "3,2365625106"

b = CSng(a) 'Результат: 3,236562

Функция CStr

Функция CStr используется для преобразования выражений в тип данных String.

Dim a As Single, b As String

a = 5106.23

b = CStr(a) 'Результат: "5106,23"

Функция CVar

Функция CVar используется для преобразования выражений в тип данных Variant.

Dim a As Double, b As String, c

a = 549258.232546

b = "Новое сообщение"

c = CVar(a) 'Результат: 549258,232546 (Variant/Double)

c = CVar(b) 'Результат: "Новое сообщение" (Variant/String)

Функции преобразования типов данных используются в тексте процедур VBA Excel для того, чтобы указать, что результатом выполнения той или иной операции должны стать данные определенного типа, отличающегося от типа, заданного по умолчанию.

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

12 комментариев для “VBA Excel. Функции преобразования типов”

0mega 06.09.2021 в 09:04

1

b = CDate(a)

эта команда прекрасно преобразует текст в дату

этот макрос позволяет выделенный диапазон представить в виде даты

1
2
3
4
5
6
7
8
9
10

Sub Text_Data()
Dim a As Variant, b As Date, c As Double
Dim r%
r = 10
For Each a In Selection
b = CDate(a)
Cells(r, "g").Value = b
r = r + 1
Next a
End Sub

но здесь новые значения получают новую прописку (новый, другой адрес)
а как сделать чтобы «b» прописывалась на месте «а»

и еще один вопрос
а можно ли обойтись без цикла ?
т.е. массиву присвоить переменную

1

q=array (selection)

а потом

1

b = CDate(q)
1. Евгений 06.09.2021 в 20:28
  
  По первому вопросу: a = CDate(a)
  По второму вопросу: массив не может быть аргументом функции CDate.
Сбитый Лётчик Небосводов 29.08.2022 в 08:47

Здравствуйте, Евгений!
Здравствуйте, коллеги!
Почему

1
2
3

Dim x!
Пустая_ячейка = Replace(Пустая_ячейка, " ", "")
x = CSng(Пустая_ячейка)

работает, а

1

x = CSng(Replace(Пустая_ячейка, " ", ""))

выдаёт Type mismatch?

Евгений 29.08.2022 в 18:05

Добрый день!
Если Пустая_ячейка имеет общий формат, то пустая строка, возвращенная выражением Replace(Пустая_ячейка, " ", ""), преобразуется в ней в Empty, и функция CSng(Пустая_ячейка) возвращает ноль. Если задать этой ячейке текстовый формат, то x = CSng(Пустая_ячейка), как и выражение x = CSng(Replace(Пустая_ячейка, " ", "")), выдаст ошибку Type mismatch.

Проверочный код:

1
2

x = CSng(Empty)
MsgBox x

Сбитый Лётчик Небосводов 30.08.2022 в 15:08

Увы, формат Общий ни на что не влияет в этом случае. Код

1
2
3
4
5
6

Sub tmp()
Dim x!
Cells(1, 1) = Replace(Cells(1, 1), " ", "")
x = CSng(Cells(1, 1))
x = CSng(Replace(Cells(1, 1), " ", ""))
End Sub

спотыкается Type mismatch на последней строке, какой бы тип у Cells(1, 1) ни был, если она пустая. А

1
2
3
4

Sub tmp()
Dim x!
x = CSng(Replace(Cells(1, 1), " ", ""))
End Sub

работает при «1 2» в Cells(1, 1) любого типа.

Евгений 30.08.2022 в 18:16

Я об этом:

Sub tmp1()

Dim x!

Cells(1, 1).ClearContents

Cells(1, 1).NumberFormat = "General"

Cells(1, 1) = Replace(Cells(1, 1), " ", "")

x = CSng(Cells(1, 1)) ' Результат: 0 (CSng(Empty))

MsgBox x

End Sub

Sub tmp2()

Dim x!

Cells(1, 1).ClearContents

Cells(1, 1).NumberFormat = "@"

Cells(1, 1) = Replace(Cells(1, 1), " ", "")

x = CSng(Cells(1, 1)) ' Результат: Type mismatch (CSng(""))

MsgBox x

End Sub

1. Сбитый Лётчик Небосводов 30.08.2022 в 18:40
  
  Большое спасибо за участие, Евгений.
  Но ясности нет. Если в Sub tmp1() заменить
  
  1
  2
  
  Cells(1, 1) = Replace(Cells(1, 1), " ", "")
  x = CSng(Cells(1, 1))
  
  на
  
  1
  
  x = CSng(Replace(Cells(1, 1), " ", ""))
  
  то всё тот же Type mismatch.
2. 1. Евгений 30.08.2022 в 21:26
    
    Функция Replace всегда возвращает строку. CSng(строка) вызывает Type mismatch. Если строка может интерпретироваться как число, например: «256», VBA преобразует его в аргументе функции CSng в число, а пустую строку в ноль не преобразовывает:
    
    1
    2
    3
    
    MsgBox CSng("256") 'Результат: 256
    MsgBox CSng("0") 'Результат: 0
    MsgBox CSng("") 'Результат: Type mismatch
    
    Если ячейка Cells(1, 1) содержит Empty или пустую строку, выражение Replace(Cells(1, 1), " ", "") возвращает пустую строку, и, соответственно, CSng(Replace(Cells(1, 1), " ", "")) возвращает ошибку Type mismatch.
  2. 1. Сбитый Лётчик Небосводов 31.08.2022 в 04:48
      
      Replace(Cells(1, 1), " ", "") возвращает пустую строку.
      Стало быть, после Cells(1, 1) = Replace(Cells(1, 1), " ", "") в Cells(1, 1) пустая строка.
      Тогда, по-Вашему, и CSng(Cells(1, 1)) тоже должен давать Type mismatch, но этого в Sub tmp1() не происходит.
    2. 1. Евгений 31.08.2022 в 09:50
        
        Это я уже объяснил ранее: в Sub tmp1() ячейке Cells(1, 1) присваивается общий формат, при котором пустая строка, возвращенная выражением Cells(1, 1) = Replace(Cells(1, 1), " ", ""), автоматически преобразуется в Empty, а CSng(Empty) возвращает ноль. В Sub tmp2(), где ячейке Cells(1, 1) присваивается текстовый формат, преобразования пустой строки в Empty не происходит, и CSng("") генерирует ошибку Type mismatch.
      2. Сбитый Лётчик Небосводов 31.08.2022 в 10:16
        
        Так почему код
        
        1
        2
        3
        4
        5
        6
        
        Sub tmp3()
        Dim x!
        Cells(1, 1).ClearContents
        Cells(1, 1).NumberFormat = "General"
        x = CSng(Replace(Cells(1, 1), " ", ""))
        End Sub
        
        даёт Type mismatch несмотря на присвоение общего формата и автоматического преобразования Replace’ом в Empty?
        
        Евгений 31.08.2022 в 10:32
        
        А где вы видите преобразование в ячейке: x = CSng(Replace(Cells(1, 1), " ", ""))? Преобразование в ячейке: Cells(1, 1) = Replace(Cells(1, 1), " ", "")!

Обсуждение закрыто.