VBA Excel. Метод Range.AutoFill (автозаполнение ячеек)

Параметр	Описание
Destination	Диапазон ячеек, который необходимо заполнить. В него должен быть включен исходный диапазон (Expression). Обязательный параметр.
Type	Константа из коллекции XlAutoFillType, задающая тип автозаполнения. Необязательный параметр.

Константа из коллекции XlAutoFillType указывает, как должен быть заполнен целевой диапазон (Destination) в зависимости от содержимого диапазона исходных данных (Expression). По умолчанию используется константа xlFillDefault (0), когда приложение Excel само определяет значения и форматы, используемые для заполнения целевого диапазона.

Примеры с Range.AutoFill

Примеры автозаполнения целевых диапазонов из кода VBA Excel с помощью метода AutoFill объекта Range.

Пример 1

Автозаполнение указанного диапазона (Destination), состоящего из нескольких строк и столбцов, данными одной ячейки (Expression) в зависимости от ее расположения в целевом диапазоне:

Sub Primer1()

'Удаляем границы ячеек, если уже были запуски кода

Range("A1:E20").Borders.LineStyle = xlNone

'Ячейка Expression в верхнем левом углу Destination

Range("A1") = 111

Range("A1").AutoFill Range("A1:E5")

Range("A1:E5").Borders(xlEdgeBottom).LineStyle = True

'Ячейка Expression в нижнем левом углу Destination

Range("A10") = 222

Range("A10").AutoFill Range("A6:E10")

Range("A6:E10").Borders(xlEdgeBottom).LineStyle = True

'Ячейка Expression в верхнем правом углу Destination

Range("E11") = 333

Range("E11").AutoFill Range("A11:E15")

Range("A11:E15").Borders(xlEdgeBottom).LineStyle = True

'Ячейка Expression в нижнем правом углу Destination

Range("E20") = "444"

Range("E20").AutoFill Range("A16:E20")

End Sub

Целевые диапазоны для наглядности разделены горизонтальными линиями. Ячейка (Expression) может находиться только по углам целевого диапазона (Destination), иначе будет сгенерирована ошибка.

Пример 2

Горизонтальное автозаполнение указанного диапазона (Destination) последовательностью чисел, месяцев и дней недели:

Sub Primer2()

'Удаляем границы ячеек, если уже были запуски кода

Range("A1:L4").Borders.LineStyle = xlNone

'Автозаполнение строки единицами

Range("A1") = 1

Range("A1").AutoFill Range("A1:L1")

Range("A1:L1").Borders(xlEdgeBottom).LineStyle = True

'Автозаполнение строки последовательностью натуральных чисел

Range("A2") = 1

Range("B2") = 2

Range("A2:B2").AutoFill Range("A2:L2")

Range("A2:L2").Borders(xlEdgeBottom).LineStyle = True

'Одновременное заполнение одной строки последовательностью

'месяцев и второй строки - днями недели

Range("A3") = "Январь"

Range("A4") = "Понедельник"

Range("A3:A4").AutoFill Range("A3:L4")

End Sub

Пример 3

Вертикальное автозаполнение указанного диапазона (Destination) последовательностью дат:

Sub Primer3()

'Автозаполнение столбца датами, начиная с текущей

Range("A1") = Date

Range("A1").NumberFormat = "DD.MM.YYYY"

Range("A1").AutoFill Range("A1:A20")

'Автозаполнение столбца датами в обратном порядке

Range("B20") = Date

Range("B20").NumberFormat = "DD.MM.YYYY"

Range("B20").AutoFill Range("B1:B20")

End Sub

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

1 комментарий для “VBA Excel. Метод Range.AutoFill (автозаполнение ячеек)”

Роман 13.03.2023 в 14:38

Добрый день
Подскажите почему не работает в диапазоне если его сместить от начала листа, работает построчно хорошо в любом месте.
а диапазон не получается выдает ошику
'Sub Primerh2_13_2_1() 'No не работает в диапазоне _ только в строке- Автозаполнение указанного диапазона ' ThisWorkbook.Worksheets("33Primer").Activate: Range("A75").Select ' Range("A75:E90").Borders.LineStyle = xlNone 'Удаляем границы ячеек, _ ' если были запуски кода ' Range("A75") = 111 'Ячейка Expression в верхнем левом углу Destination ' Range("A75").AutoFill Range("A75:E77") ', xlFillDefault end sub

Обсуждение закрыто.