VBA Excel. Создание таблиц в документе Word

Создание таблиц в документе Word из кода VBA Excel. Метод Tables.Add, его синтаксис и параметры. Объекты Table, Column, Row, Cell. Границы таблиц и стили.

Работа с Word из кода VBA Excel
Часть 4. Создание таблиц в документе Word
[Часть 1] [Часть 2] [Часть 3] [Часть 4] [Часть 5]

Содержание

1. Создание таблиц в документе Word

1.1. Синтаксис метода Tables.Add

1.2. Параметры метода Tables.Add

1.3. Создание таблицы в документе

1.4. Отображение границ таблицы

1.5. Присвоение таблицам стилей

1.6. Обращение к ячейкам таблицы

2. Примеры создания таблиц Word

Создание таблиц в документе Word

Таблицы в VBA Word принадлежат коллекции Tables, которая предусмотрена для объектов Document, Selection и Range. Новая таблица создается с помощью метода Tables.Add.

Синтаксис метода Tables.Add

1	Expression.Add (Range, Rows, Columns, DefaultTableBehavior, AutoFitBehavior)

Expression – выражение, возвращающее коллекцию Tables.

Параметры метода Tables.Add

Range – диапазон, в котором будет создана таблица (обязательный параметр).
Rows – количество строк в создаваемой таблице (обязательный параметр).
Columns – количество столбцов в создаваемой таблице (обязательный параметр).
DefaultTableBehavior – включает и отключает автоподбор ширины ячеек в соответствии с их содержимым (необязательный параметр).
AutoFitBehavior – определяет правила автоподбора размера таблицы в документе Word (необязательный параметр).

Создание таблицы в документе

Создание таблицы из 3 строк и 4 столбцов в документе myDocument без содержимого и присвоение ссылки на нее переменной myTable:

With myDocument

Set myTable = .Tables.Add(.Range(Start:=0, End:=0), 3, 4)

End With

Создание таблицы из 5 строк и 4 столбцов в документе Word с содержимым:

With myDocument

myInt = .Range.Characters.Count - 1

Set myTable = .Tables.Add(.Range(Start:=myInt, End:=myInt), 5, 4)

End With

Для указания точки вставки таблицы присваиваем числовой переменной количество символов в документе минус один. Вычитаем единицу, чтобы исключить из подсчета последний знак завершения абзаца (¶), так как точка вставки не может располагаться за ним.

Последний знак завершения абзаца всегда присутствует в документе Word, в том числе и в новом без содержимого, поэтому такой код подойдет и для пустого документа.

При создании, каждой новой таблице в документе присваивается индекс, по которому к ней можно обращаться:

1	myDocument.Tables(индекс)

Нумерация индексов начинается с единицы.

Отображение границ таблицы

Новая таблица в документе Word из кода VBA Excel создается без границ. Отобразить их можно несколькими способами:

Вариант 1
Присвоение таблице стиля, отображающего все границы:

1	myTable.Style = "Сетка таблицы"

Вариант 2
Отображение внешних и внутренних границ в таблице:

With myTable

.Borders.OutsideLineStyle = wdLineStyleSingle

.Borders.InsideLineStyle = wdLineStyleSingle

End With

Вариант 3
Отображение всех границ в таблице по отдельности:

With myTable

.Borders(wdBorderHorizontal) = True

.Borders(wdBorderVertical) = True

.Borders(wdBorderTop) = True

.Borders(wdBorderLeft) = True

.Borders(wdBorderRight) = True

.Borders(wdBorderBottom) = True

End With

Присвоение таблицам стилей

Вариант 1

1	myTable.Style = "Таблица простая 5"

Чтобы узнать название нужного стиля, в списке стилей конструктора таблиц наведите на него указатель мыши. Название отобразится в подсказке. Кроме того, можно записать макрос с присвоением таблице стиля и взять название из него.

Вариант 2

1	myTable.AutoFormat wdTableFormatClassic1

Выбирайте нужную константу с помощью листа подсказок свойств и методов – Auto List Members.

Обращение к ячейкам таблицы

Обращение к ячейкам второй таблицы myTable2 в документе myDocument по индексам строк и столбцов:

1 2	myTable2.Cell(nRow, nColumn) myDocument.Tables(2).Cell(nRow, nColumn)

nRow – номер строки;
nColumn – номер столбца.

Обращение к ячейкам таблицы myTable в документе Word с помощью свойства Cell объектов Row и Column и запись в них текста:

myTable.Rows(2).Cells(2).Range = _

"Содержимое ячейки во 2 строке 2 столбца"

myTable.Columns(3).Cells(1).Range = _

"Содержимое ячейки в 1 строке 3 столбца"

В таблице myTable должно быть как минимум 2 строки и 3 столбца.

Примеры создания таблиц Word

Пример 1
Создание таблицы в новом документе Word со сплошными наружными границами и пунктирными внутри:

Sub Primer1()

Dim myWord As New Word.Application, _

myDocument As Word.Document, myTable As Word.Table

Set myDocument = myWord.Documents.Add

myWord.Visible = True

With myDocument

Set myTable = .Tables.Add(.Range(0, 0), 5, 4)

End With

With myTable

.Borders.OutsideLineStyle = wdLineStyleSingle

.Borders.InsideLineStyle = wdLineStyleDot

End With

End Sub

В выражении myDocument.Range(Start:=0, End:=0) ключевые слова Start и End можно не указывать – myDocument.Range(0, 0).

Пример 2
Создание таблицы под ранее вставленным заголовком, заполнение ячеек таблицы и применение автосуммы:

Sub Primer2()

On Error GoTo Instr

Dim myWord As New Word.Application, _

myDocument As Word.Document, _

myTable As Word.Table, myInt As Integer

Set myDocument = myWord.Documents.Add

myWord.Visible = True

With myDocument

'Вставляем заголовок таблицы

.Range.InsertAfter "Продажи фруктов в 2019 году" & vbCr

myInt = .Range.Characters.Count - 1

'Присваиваем заголовку стиль

.Range(0, myInt).Style = "Заголовок 1"

'Создаем таблицу

Set myTable = .Tables.Add(.Range(myInt, myInt), 4, 4)

End With

With myTable

'Отображаем сетку таблицы

.Borders.OutsideLineStyle = wdLineStyleSingle

.Borders.InsideLineStyle = wdLineStyleSingle

'Форматируем первую и четвертую строки

.Rows(1).Range.Bold = True

.Rows(4).Range.Bold = True

'Заполняем первый столбец

.Columns(1).Cells(1).Range = "Наименование"

.Columns(1).Cells(2).Range = "1 квартал"

.Columns(1).Cells(3).Range = "2 квартал"

.Columns(1).Cells(4).Range = "Итого"

'Заполняем второй столбец

.Columns(2).Cells(1).Range = "Бананы"

.Columns(2).Cells(2).Range = "550"

.Columns(2).Cells(3).Range = "490"

.Columns(2).Cells(4).AutoSum

'Заполняем третий столбец

.Columns(3).Cells(1).Range = "Лимоны"

.Columns(3).Cells(2).Range = "280"

.Columns(3).Cells(3).Range = "310"

.Columns(3).Cells(4).AutoSum

'Заполняем четвертый столбец

.Columns(4).Cells(1).Range = "Яблоки"

.Columns(4).Cells(2).Range = "630"

.Columns(4).Cells(3).Range = "620"

.Columns(4).Cells(4).AutoSum

End With

'Освобождаем переменные

Set myDocument = Nothing

Set myWord = Nothing

'Завершаем процедуру

Exit Sub

'Обработка ошибок

Instr:

If Err.Description <> "" Then

MsgBox "Произошла ошибка: " & Err.Description

End If

If Not myWord Is Nothing Then

myWord.Quit

Set myDocument = Nothing

Set myWord = Nothing

End If

End Sub

Метод AutoSum суммирует значения в ячейках одного столбца над ячейкой с суммой. При использовании его для сложения значений ячеек в одной строке, результат может быть непредсказуемым.

Чтобы просуммировать значения в строке слева от ячейки с суммой, используйте метод Formula объекта Cell:

1	myTable.Cell(2, 4).Formula ("=SUM(LEFT)")

Другие значения метода Formula, применяемые для суммирования значений ячеек:

«=SUM(ABOVE)» – сумма значений над ячейкой (аналог метода AutoSum);
«=SUM(BELOW)» – сумма значений под ячейкой;
«=SUM(RIGHT)» – сумма значений справа от ячейки.

Дополнительная информация к этой теме: Вставка таблицы Excel в документ Word.

Содержание рубрики VBA Excel по тематическим разделам со ссылками на все статьи.

12 комментариев для “VBA Excel. Создание таблиц в документе Word”

Юрий 27.07.2021 в 06:14

Спасибо автору сайта за подробное описание и примеры.
Вопрос по записи макроса в Word 2003.
Нужно реализовать отключение макросом автоподбора размеров таблицы по содержимому (Свойства таблицы — Таблицы — Параметры). При попытке записать макрос Свойства таблицы оказываются недоступными.
Подскажите код, который будет отключать автоподбор размеров таблицы по содержимому.
Спасибо.

Ответить

Евгений 27.07.2021 в 11:39

Здравствуйте, Юрий!
Попробуйте так:

1

ActiveDocument.Tables(1).AllowAutoFit = False

Ответить
1. Юрий 27.07.2021 в 22:33
  
  Евгений, спасибо огромное!
  Конструкция работает — в таблице, вставленной макросом из Excel в Word ширина столбцов остаётся такой же как и в Excel.
  
  Ответить

Андрей 30.07.2021 в 14:34

Здравствуйте Евгений!
Может Вы подскажете в чем дело.
Нужно вставить несколько диапазонов ячеек из Excel в Word.
Эти диапазоны могут быть разной высоты (разное количество строк и разная высота строк)
Нужно, чтобы каждый диапазон располагался на отдельном листе Word.
Руками я делаю так: на листе Word рисую таблицу из одной ячейки и в неё вставляю нужную таблицу Excel.
Сделал макрос, который вставляет нужные диапазоны ячеек в документ из шаблона Word по
меткам {Табл1} {Табл2} {Табл3} и т.д.
Всё отлично работает, но страницы «съезжают» т.к. высота вставляемых диапазонов (количество и высота строк в них) меняется.
Если в шаблоне Word рисую таблицу из одной ячейки на весь лист, в которую ставлю метку, например, {Табл2},
то VBA вставляет таблицу ВЫШЕ ячейки на листе Word. Причем, метка {Табл2} остается внутри ячейки.

Set tbl2Range = Range(Cells(35, 8), Cells(39 + s, 12))

tbl2Range.Copy

FindText = "{Табл2}"

WD.Application.Selection.Find.ClearFormatting

If WD.Application.Selection.Find.Execute(FindText) = True Then

WD.Application.Application.Selection.Paste

End If

Помогите пожалуйста!

Ответить

Евгений 31.07.2021 в 01:01

Здравствуйте, Андрей!
У меня нет решения. Тесты дают тот же результат: вставка таблицы происходит перед ячейкой без замещения закладки. При конкретном указании ячейки с закладкой:

1

myDocument.Tables(1).Columns(1).Cells(1).Range.Paste

закладка замещается значением первой ячейки вставляемой таблицы.

Ответить

Андрей 31.07.2021 в 12:10

Спасибо за отклик!
Частично разобрался, работает такой код:

With WA

.Visible = True

.ActiveDocument.Tables(1).cell(1, 1).Select

End With

Sheets("Док").Activate

Range(Cells(4, 2), Cells(i, 5)).Select

Selection.Copy

WA.Selection.PasteExcelTable _

LinkedToExcel:=False, _

WordFormatting:=False, _

RTF:=False

Но у меня несколько таблиц в Wordе, в которые нужно вставлять таблицы из Excel
Во вторую таблицу уже попасть не могу 🙁
Код

1	.ActiveDocument.Tables(2).cell(1, 1).Select

во вторую нарисованную таблицу в шаблоне не попадает.
Как обозначаются явно таблицы в Worde?

Ответить

Евгений 31.07.2021 в 13:20

В таблицу можно попасть только по ее порядковому номеру или по закладке в ней. У вас, в приведенном коде, одной буквы не хватает:

1
2

.ActiveDocument.Tables(2).cell(1, 1).Select
.ActiveDocument.Tables(2).Cells(1, 1).Select

Если это не опечатка, тогда из-за этого не работает.

Ответить
1. Андрей 31.07.2021 в 13:48
  
  заработало с Tables(3)
  Хотя таблица по порядку в документе вторая.
  И код
  
  1
  
  .ActiveDocument.Tables(3).cell(1, 1).Select
  
  именно такой — cell(1,1) работает.
  Когда разбирался, пробовал cell(1,10) VBA сказал, что нет такой ячейки
  
  Ответить

Алексей 23.04.2022 в 16:29

Здравствуйте, Евгений. Я не могу вставить автоподбор ширины ячеек в ваш код по вставке в ворд.

Sub Primer()

Dim myWord As New Word.Application, myDoc As Word.Document

'Открываем существующий документ Word

Set myDoc = myWord.Documents.Open("C:\Тестовая\Документ1.docx")

'Копируем таблицу на активном листе в буфер обмена

'Вместо ячейки Range("A1") можно указать любую другую, расположенную внутри таблицы

Range("A1").CurrentRegion.Copy

'Вставляем таблицу из буфера обмена на место закладки

myDoc.Bookmarks("Закладка1").Range.PasteExcelTable False, False, False

'Отображаем программу Word

myWord.Visible = True

With myDocument

Set myTable = .Expression.Add (DefaultTableBehavior)

End With

Set myWord = Nothing

Set myDoc = Nothing

End Sub

Ответить

1. Евгений 24.04.2022 в 01:09
  
  Здравствуйте, Алексей!
  Попробуйте так:
  
  1
  
  myDoc.Tables(2).AutoFitBehavior wdAutoFitWindow
  
  У меня это сработало. Замените 2 на порядковый номер вашей таблицы.
  Замечание по вашему участку кода: объявлена переменная myDoc, а вы используете в блоке With переменную myDocument.
  
  Ответить
Алексей 24.04.2022 в 09:48

Здравствуйте, Евгений. Извините меня, я не написал, что этим кодом я хотел добиться. При вставке кодом из Excel в документ Word у меня таблица немного сжимается и соответственно текстовые строки делают перенос, а при выполнении в Word для таблицы автоформат по содержимому у меня встаёт всё на места. Вот и пытался приспособить код. Ваш код работает, но мою проблему не решает. Из вашего объяснения понял, что не то делаю. Спасибо вам за ваше внимание. Буду искать решение дальше.

Ответить

Алексей 24.04.2022 в 11:18

Решил попробовать выполнить макрос Word из Excel. Записывая рекордером Word действия (нажал автоподбор и выбрал автоподбор по содержимому) мне выдал такой код:

Sub Макрос1()

' Макрос1 Макрос

Selection.Tables(1).AutoFitBehavior (wdAutoFitContent)

End Sub.

дважды повторяет тот же код (ещё раз, выше код, это код макроса Word).
Вернулся к вашему коду поправил скобки и всё равно не работал. Установил:

1	myDoc.Tables(1).AutoFitBehavior (wdAutoFitContent)

как в коде Word и Ура, всё встало как надо. Спасибо вам.

Ответить

VBA Excel. Создание таблиц в документе Word

Создание таблиц в документе Word

Синтаксис метода Tables.Add

Параметры метода Tables.Add

Создание таблицы в документе

Отображение границ таблицы

Присвоение таблицам стилей

Обращение к ячейкам таблицы

Примеры создания таблиц Word

12 комментариев для “VBA Excel. Создание таблиц в документе Word”

Добавить комментарий Отменить ответ